How to set Gradle Artifactory Publish plugin default configuration/properties from custom plugin

Question

I have been trying to set the properties of publish(PublisherConfig), defaults(defaultsClosure) from my custom plugin. What is the best way to do this ?

I tried the following;

Approach 1: Tried setting the properties on the extensions project.getExtensions().publishing.getProperties().each { println it }

Approach 2: Tried adding compile time dependency on the Gradle Artifactory plugin and importing the plugin classes... ```

        if (project.plugins.hasPlugin("com.jfrog.artifactory")) {
            println "I found jfrog.artifactory plugin"
            Plugin jfrogArtifactory = project.getPlugins().getPlugin("com.jfrog.artifactory")

            ArtifactoryPluginConvention apc = new ArtifactoryPluginConvention(project);
            project.getExtensions().add("artifactory", apc);

            apc.contextUrl = 'https://myrepo.com/artifactory/'


            PublisherConfig pc = new PublisherConfig(apc);

            pc.defaults {
                println "in my plugin pc.defaults : " + it.metaClass

                publications('mavenJava')
                publishConfigs('archives', 'published')


                properties = ['my.gitCommitUrl': project.getExtensions().findByType(BuildPropertiesPluginExtension.class).gitCommitUrl, 'my.gitHash': project.getExtensions().findByType(BuildPropertiesPluginExtension.class).gitHash, 'my.gitBranch': project.getExtensions().findByType(BuildPropertiesPluginExtension.class).gitBranch]
                publishBuildInfo = true   //Publish build-info to Artifactory (true by default)
                publishArtifacts = true   //Publish artifacts to Artifactory (true by default)
                publishPom = true   //Publish generated POM files to Artifactory (true by default).
                publishIvy = false   //Publish generated Ivy descriptor files to Artifactory (true by default).

            }

            pc.repository {
                println "in my plugin pc.repository : " + it.metaClass
                repoKey = 'my-mvn'   //The Artifactory repository key to publish to
                username = project.findProperty("artifactory_user") ?: ""          //The publisher user name
                password = project.findProperty("artifactory_api_key") ?: ""       //The publisher password
            }

            apc.setPublisherConfig(pc)

        }

```

Compile and Build are successful, artifact and its info is not published.

:artifactoryPublish

BUILD SUCCESSFUL

Total time: 3.313 secs

ravikanth ravikanth · Accepted Answer · 2016-09-06T07:46:08

Here is what worked for me!!!

`

        if (project.plugins.hasPlugin("com.jfrog.artifactory")) {
            Plugin jfrogArtifactory = project.getPlugins().getPlugin("com.jfrog.artifactory")

            //maven install task is required to publishPom (using artifactory plugin)
            if (!project.plugins.hasPlugin("maven")) {
                project.apply(plugin: MavenPlugin)
            }

            Closure artifactoryPublishClosure = {
                contextUrl = 'https://myrepo.com/artifactory/'

                publications('mavenJava')

                publishConfigs('archives', 'published')

                properties = ['gitCommitUrl': project.getExtensions().findByType(BuildPropertiesPluginExtension.class).gitCommitUrl, 'gitHash': project.getExtensions().findByType(BuildPropertiesPluginExtension.class).gitHash, 'gitBranch': project.getExtensions().findByType(BuildPropertiesPluginExtension.class).gitBranch]

                publishBuildInfo = true   //Publish build-info to Artifactory (true by default)
                publishArtifacts = true   //Publish artifacts to Artifactory (true by default)
                publishPom = true   //Publish generated POM files to Artifactory (true by default).
                publishIvy = false   //Publish generated Ivy descriptor files to Artifactory (true by default).

                // Redefine basic properties of the build info object
                clientConfig.setIncludeEnvVars(true)
                clientConfig.timeout = 600 // Artifactory connection timeout (in seconds). The default timeout is 300 seconds.

                publish {
                    //A closure defining publishing information
                    repository {
                        repoKey = 'my-mvn'   //The Artifactory repository key to publish to
                        username = project.findProperty("artifactory_user") ?: ""          //The publisher user name
                        password = project.findProperty("artifactory_api_key") ?: ""       //The publisher password
                    }
                }

                resolve {
                    repository {
                        repoKey = 'my-mvn'  //The Artifactory (preferably virtual) repository key to resolve from
                    }
                }

            }

            project.getTasks().findByName("artifactoryPublish").configure(artifactoryPublishClosure)
        }

`

How to set Gradle Artifactory Publish plugin default configuration/properties from custom plugin

1 Answers