Cast ActionScript Object to Model

Question

Is there any "automatic way" to casts an "Object" to a personalized Model Data Type in ActionScript 3?

Example:

package Example{
   public class ExampleModel{
       private _id:int;
       private _randomAttribute:String;

       public function ExampleModel(){
           _id = 0;
           _randomAttribute = "";
       }

       public function get id():int{
           return _id;
       }

       public function set id(value:int):void{
           _id = value;
       }

       public function get randomAttribute():String{
           return _randomAttribute;
       }

       public function set randomAttribute(value:String):void{
           _randomAttribute = value;
       }
   }
}

Then, in some part of my code, lets assume that I have something like this:

var _obj:Object = new Object();
_obj.id = 1;
obj.randomAttribute = "Hello World";

What I want would be something like:

var _exampleModel:ExampleModel = obj as ExampleModel;

But when I do this, the result on _exampleModel is null. Any ideas? Thanks.

EDIT:

According to Manish's answer, all I changed was the type of p var, which allows me to go through every kind of attribute:

public function fromObject(obj:Object):void{
    //p:* includes every type of attributes.
    for (var p:* in obj)
        if (this.hasOwnProperty(p))
            // Set private var directly.
            this["_" + p] = obj[p];
}

Thanks Manish and rcdmk. Manish's answer was enough for me and according to rcdmk's comment, the p:String isn't about the Type of data that the loop will go through, it is actually the name of the property, which makes sense because every name is a String.

Can you tell us more about why you're trying to achieve this? This goes against the grain of ActionScript's design, and there's probably a better way to achieve your goals. — Dan Wich
When a user double clicks a record on a dataGrid, I automatically open a different state that contains the form for that entity and fill all the fields with his register (dataGridId.selectedItem). But this is an Object and when I'm going to send this for PHP, I "manually" cast the whole form to a Personalized Model. If I can bound the form with the Model, I no longer need to go through all the fields and set the Model attribute one by one. — Marco Aurélio Deleu

Manish Manish · Accepted Answer · 2012-03-04T20:19:55

The only way to automatically "cast" it is the following:

var model:Model = new Model();
var obj:Object = { id: "98123", name: "John Doe" };

for (var p:String in obj) {
    if (model.hasOwnProperty(p))
        model[p] = obj[p];
}

(Note: Model.id and Model.name are both type String in my example.)

A more proper way to do it, of course, is to pass the plain object to the Model object and let the Model object absorb it.

var model:Model = new Model(obj);

Or:

var model:Model = new Model();
model.fromObject(obj);

Where in the Model code you have:

public function Model(obj:Object = null)
{
    if (obj != null)
        fromObject(obj);
}

public function fromObject(obj:Object):void
{
    for (var p:String in obj)
        if (this.hasOwnProperty(p))
            // Set private var directly.
            this["_" + p] = obj[p];
}

This code can be in your abstract base Model class, and all your specific Model subclasses (e.g. ProductModel, CustomerModel, etc.) can use it automatically.

e.g.

public class ProductModel extends Model
{
    public function ProductModel(obj:Object = null)
    {
        super(obj);
    }
}

Cast ActionScript Object to Model

1 Answers