Gnuplot histogram labels

Question

I have one minor problem: I need the corresponding heigh value for each histogram box, but only get one. The code and the image is attached below. Thank you all in advance!

The input file has the following data structure, all in one line:

large 7995 medium 11 small 1


set terminal png
set term pngcairo dashed
set title  " Grain Size vs N of Zones"
set ylabel "N of zones"
set style fill solid 1.0
 
set yr [0.0:8500]

filename2(n) = sprintf("f_vs_a_%03.0f_25.dat", n)
outfile  (n) = sprintf("f_vs_a_%03.0f_25.png", n)


set style data histograms

do for [N=1:86] {
    set output outfile(N)
    infile = filename2(N)

    plot for [i=N:N] filename2  (i) using 2:xtic(2)  title 'large',\
         for [i=N:N] filename2  (i) using 4:xtic(4)  title 'medium',\
         for [i=N:N] filename2  (i) using 4:xtic(4)  title 'small',\
                 
       }
EOF

theozh theozh · Accepted Answer · 2021-12-17T20:14:57

First, your values differ by orders of magnitude 7996 and 11 and 1. It might be difficult to see 11 and 1 if you are not in logscale. Second, you have two identical lines with using 4:xtic(4).

Assuming I understood your intention, I would do something like this (just as an example without your loop but with logscale plot):

Code:

### plotting a row including titles
reset session

$Data <<EOD
large 7995 medium 11 small 1
EOD

set xrange[0.5:3.5]
set yrange [0:10000]
set boxwidth 0.8 
set style fill solid 1.0

set multiplot layout 2,1

    array myTitles[3]
    plot for [i=1:3] $Data u (i):(myTitles[i]=strcol(2*i-1), column(2*i)):xtic(2*i) w boxes notitle, \
    for [i=1:3] keyentry w boxes lc i title myTitles[i]

    set logscale y
    replot

unset multiplot
### end of code

Result:

Gnuplot histogram labels

1 Answers