Polishing gnuplot histogram plot

Question

I am trying to plot some execution times of certain datasets 1, 2 and 3 using from 1 up to 12 threads. Based on hints from other collaborators, I've managed to plot something, but is still raw and needs a few modifications.

test.dat files looks like this:

It is organized this way: First 10 lines are execution times for dataset 1 and 1 thread; the next 10 are times for dataset 2 and 1 thread; the 10 next dataset 3, 1 thread, and so on for up to 12 number of threads.

The gnuplot script looks like this:

set boxwidth 0.7 relative
set style fill solid 1.0 noborder
set xtics ("1" 15, "2" 75, "3" 135, "4" 195, "5" 255, "6" 315, "7" 375, "8" 435, "9" 495, "10" 555, "11" 615, "12" 675)
unset key
set terminal png size 800,600 enhanced font "Helvetica,10"
set output 'output.png'
set xlabel "Number of threads"
set ylabel "Execution time"
plot for [i=1:12] 'test.dat' using ($0+(i-1)*60):1 every ::((i-1)*30)::(i*30-1) with boxes lt i

There are a few issues with this plot:

The datasets: as we can see there are 10 executions for each dataset, for each number of threads. Dataset 1 are the lowest values, ds 2 the medium values and ds 3 the highest values. Instead of one color for each number of threads, there should only be 3 colors, say red for dataset 1, green for dataset 2 and blue for dataset 3 and these should be informed via set key upper right.
The spacing: plot begins glued to left y axis. There should be a spacing of, say, 15 units before the first histogram and the left y axis, a few units between datasets, again 15 units in between the numbers of threads and 15 units between the last histogram and the right y axis.
The xtics: xtics should take in account the spacing aforementioned. Is it possible to loop the setting of those xtics?

Thanks in advance.

UPDATE

Matthew, based on your assertion of point 1, here are the execution times sorted by dataset (dataset 1: lines 1 - 120; dataset 2: lines 121 - 240; dataset 3: lines 241 - 360); first 10 lines of the given ds stand for execution times for 1 thread, the 10 next for 2 threads, and so on.

I'm also posting what the plot looked like before so you can measure up how much you've helped in improving:

I expanded my answer to provide a plot command for the sorted dataset, so that it is complete and covers both forms of the dataset you have provided. Note that with the sorted data set the every selection is simpler, there is only one for (as we don't have to deal with interweaving), and the title specification is simpler. The x-coordinate computation becomes slightly more complex, but overall it is a simpler command. — Matthew

Matthew Matthew · Accepted Answer · 2016-04-06T06:48:29

I believe that this will accomplish what you want:

set xlabel "Number of threads"
set ylabel "Execution time"

set style fill solid 1.0 noborder

set boxwidth 0.7

set xtics ("1" 19.5)
set for[i=2:12] xtics add (sprintf("%d",i) (i-1)*55+19.5) 

set key top right

set xrange[-15:660]

plot for [i=0:2] for [j=0:9] 'test.dat' using ($0*55+j+i*15):1 every 30::(i*10+j) with boxes lt (i+1) t (j==0)?sprintf("Data Set %d",i+1):""

Here we are inserting the 15 units at both edges, between threads, and 5 units between datasets. I have also set the boxwidth to be absolute instead of relative.

The result is the following:

Addressing your points:

Point 3

Yes, it is possible to look the setting of the x-tics, using the set for syntax. Here, I specify the first xtic explicitly. This has the effect of shutting off all tics but the ones that I specify, and then I use the set xtics add command to add the additional xtics. If I hadn't explicitly set the first, I would have gotten the automatically generated tics in addition to mine.

Alternatively, we could have built up the command in a string and then executed it, using

tcommand = "("
do for[i=1:12] {tcommand = sprintf("%s \"%d\" %f,",tcommand,i,(i-1)*55+19.5)}
tcommand = tcommand[1:strlen(tcommand)-1].")"
set xtics @tcommand

Here the contents of tcommand will be

( "1" 19.500000, "2" 74.500000, "3" 129.500000, "4" 184.500000, "5" 239.500000, "6" 294.500000, "7" 349.500000, "8" 404.500000, "9" 459.500000, "10" 514.500000, "11" 569.500000, "12" 624.500000)

However, this only works if string macros are supported.

Note the width of a thread section is 3*10 + 2*5 + 15 = 55 as there are three datasets taking up 10 spaces, 2 spaces between them of 5 spaces, and one gap of 15 spaces. The 19.5 puts the tic mark directly in the center of the center dataset.

Point 2

This can easily be handled by adjusting the xrange. If we place the first box at 0, we can start the xrange at -15 to leave the left gap. As there are 12 thread units using 55 spaces each (including gaps), we can place the end of the xrange at 660.

Point 1

This is the trickier part, and I suspect there may be a better way. In particular, the data structure makes this more difficult. If all the values for dataset one were listed followed by all of them for set 2 and so on, it would be easier. The fact that they are intermixed makes it harder.

Here the line numbers for the various thread counts and data points occur like the following:

               Data set 1
     1 thread   2 threads   3 threads ...
1st  0          30          60
2nd  1          31          61
...

               Data set 2
     1 thread   2 threads   3 threads ...
1st  10         40          70
2nd  11         41          71
...

The every command does not support something like "10 consecutive lines starting every 30 points", so we need to instead do two loops. The first loop (i) will be over the data sets. The second (j) will be over the lines in the dataset (first line, second line, etc).

Thus we can read every 30th line starting at (i*10+j). For example, when i and j are both 0, we will read the 0th line, the 30th line, the 60th and so on, ie the first line in each thread set for dataset 1. Thus we can place these values at $0*55+j+i*15 where $0 ranges from 0 to 11, and thus can be used to select the thread group.

Because this means we will have 10 curves for each dataset, we set the title on only the first curve (setting it to empty suppresses it).

Here, I have used the default line types. To set a specific color for each set, the plot command can be modified, or the line types can be redefined.

EDIT:

For the sorted dataset provided by the OP, the plot command (the remaining commands are left the same) can be simplified to

plot for [i=0:2] 'test.dat' u (i*15 + floor($0/10)*55 + int($0)%10):1 every ::(i*120)::((i+1)*120-1) w boxes t sprintf("Data set %d",i+1)

Here we need only to loop over the datasets. There is no need to loop over the lines, as we can read each dataset in one block of consecutive lines. For each data set, the every notation selects the 120 corresponding to it (lines 0 - 119, 120 - 239, 240 - 359).

To compute the x-coordinate, we compute an offset for the dataset (0 for the first, 15 for the second, and 30 for the third), corresponding to the number of 10 unit blocks used by the previous set plus the spacing of 5 units. To that we add the offset for the thread block. To get that we divide the line number (0-indexed) by 10 (number of measurements per thread) and floor the result. Thus the first ten lines gives us 0, the next 10 lines gives us 1, and so on. This tells us how many thread blocks to skip and we multiply that by the size of a thread block (55). Finally, we add the value for the line in the measurement set. We use modular arithmetic to get the actual line number with respect to the thread block instead of the dataset (0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 0, 1, 2, ...). Thus i*15 + floor($0/10)*55 + int($0)%10 gives us the x-coordinate for a measurement. Even though $0 has only whole number values, it is treated as a float, so we cast to an int in order to take the modulus.

Adding the label is much simpler, as we only need to loop over each dataset once instead of 10 times, so we don't have to worry about skipping the later loops.

Polishing gnuplot histogram plot

1 Answers

Point 3

Point 2

Point 1