Please help me with the Formula & ArrayFormula:

1
votes

I want to return TRUE for blank cells until last value (check out the Required column)

enter image description here

I tried this formula: =AND($A2="" ,$A3:$A <> "") but it didn't work.
Question 1: How can I make 2nd argument i.e. $A3:$A <> "" return true if any one cell in the range $A3:$A is Not Null? Final Formula?
(I know my formula is wrong because it doesn't check every cell in the range mentioned if it is NULL or not, how can I make it check every cell?)

Question 2: ArrayFormula for the corresponding Formula.

(Please suggest if there's any better way to get the Formula & ArrayFromula along with the solution of the method I tried)
Here is the sheet link: https://docs.google.com/spreadsheets/d/1VF38MNcP1e4ieZY47QQq1zOwGYWAmuJ2k9A0WkGYeX0/edit?usp=sharing

EDIT:

I got the Formula: =IFNA(MATCH(FALSE,ArrayFormula(isblank(A2:A)),0),0)>1
For ArrayFormula I just tried wrapping it around but it didn't work: =ARRAYFORMULA(IFNA(MATCH(FALSE,ArrayFormula(isblank(A2:A)),0),0)>1)

I just need the ArrayFormula of this Formula & please tell me what's wrong in my ArrayFormula?
Thank you!

3
google-sheetsgoogle-sheets-formulaarray-formulas

3 Answers

2
votes

Try below formula.

=ArrayFormula(A2:A10="")

For full column

=ArrayFormula(A2:A="")

enter image description here

Edit: Then use below formula.

=ArrayFormula(INDEX(A:A,2):INDEX(A:A,MAX(IF(A:A<>"",ROW(A:A),0)))="")
1
votes

I suggest this simple formula:

=ArrayFormula(NOT(A2:A))

Since any value equates to TRUE and null equates to FALSE, wrapping the range in NOT will return the opposite.

ADDENDUM:

Given additional information from poster:

=ArrayFormula(IF((A2:A="")*(ROW(A2:A)<VLOOKUP(TRUE,SORT({A2:A<>"",ROW(A2:A)},2,0),2,FALSE)),TRUE,FALSE))

1
votes

try:

=INDEX(INDIRECT("A2:A"&MAX(IF(A2:A="",,ROW(A2:A))))="")

or:

=INDEX(INDIRECT("A2:A"&MAX((A2:A<>"")*ROW(A2:A)))="")

enter image description here