Conditionally define a function inside another function in Julia

Question

Slow to learning newer julia syntax and scoping.

In Julia v1.1.1

what is the explanation for why the MWE below throws error "ff not defined" ?

N = 5;
typp = "b";
mu = 2;

function bigfun()

  function f(u,mu)
    ee = mu*u;
    return ee
  end

  function g(uv,mu)
    ee = (mu^2)*uv
    return ee;
  end

  while 1 == 1

    u = ones(N);
    if typp == "a"
      ff(u) = f(u,mu);
    elseif typp == "b"
      ff(u) = g(u,mu);
    end
    fu = ff(u);
    break;

  end

end

bigfun();

You are using global variables (N, typp, mu), which is bad for performance, and a bad idea in general. You should avoid that. (A style tip: use while true instead of while 1 == 1.) — DNF
Ok thanks. Honest (and naive) question, but what if the variables are conceptually global? — dj_a
It's the very first tip detailed in docs.julialang.org/en/v1/manual/performance-tips. Use const if you really want a global variable. — giordano

giordano giordano · Accepted Answer · 2021-01-11T02:43:01

This is a known bug in Julia: https://github.com/JuliaLang/julia/issues/15602. You can't define an inner function conditionally. There a few ways around this issue:

Define ff as an anonymous function:

    if typp == "a"
      ff = u -> f(u,mu)
    elseif typp == "b"
      ff = u -> g(u,mu)
    end
    fu = ff(u)

Define ff once, and add the conditional inside of it:

    function ff(u, typp)
      if typp == "a"
        f(u,mu)
      elseif typp == "b"
        g(u,mu)
      end
    end
    fu = ff(u, typp)

Don't define the function ff at all. You don't need to, in the example you provided, just assign fu conditionally
```
    if typp == "a"
      fu = f(u,mu)
    elseif typp == "b"
      fu = g(u,mu)
    end
```

Conditionally define a function inside another function in Julia

2 Answers