AS3 getting a textField.text on Click Event

Question

So, I'm back with more problems with my Flash App.

I have a list of several movie clips in sucession, that are "MiniInfos", containing some details about some "works". These are added to the stage in a cycle, and each time I need to add a eventlistener(MouseEvent.CLICK) to be able to click it to show more details. The problem, to know which details should come up next, I need to acess a TextField that contains the ID to be able to pass it to the next Movieclip (lets call it "BigInfo").

So, I know it sounds confusing, but ill try to summarize.

There are several MiniInfos added to the stage with TextFields like "ID: 1, ID: 2, ID: 3", etc.

I want to be able to click one and another movieclip (BigInfo) gets added to the stage with more details about it. To know which info I should pull up on the PHP, I need to know the ID from which MiniInfo I clicked.

My ideia (which didn't work) was:

//on the cycle
MiniInfo.addEventListener(MouseEvent.CLICK, OpenWorkDetails);

//further down the code
public function OpenWorkDetails(e:MouseEvent):void
        {
        trace(MiniInfo.IDTrabalhoField.text);
        //If I figure this number out, I will change it to addChild
        }

So, I get an error 1120: Access of undefined property MiniInfo.

I realize this code isnt exactly the best, so If you guys got a diferent solution in mind, feel free to share. Im still learning flash.

Thank you.

Marco Fox.

Taurayi Taurayi · Accepted Answer · 2011-04-27T15:13:34

I created a small flash application to demonstrate a different approach you can take:

FLASH

Main.as(document class):

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    [SWF(width="275", height="175")]
    public class Main extends Sprite 
    {
        private var _phpPath:String = "http://localhost/stackoverflow/minibiginfos/getBigInfo.php";
        private var _bigInfo:BigInfo;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {   
            removeEventListener(Event.ADDED_TO_STAGE, init);

            var xml:XML = <miniInfos>
                              <miniInfo id="1" text="Mini Info 1" />
                              <miniInfo id="2" text="Mini Info 2" />
                              <miniInfo id="3" text="Mini Info 3" />
                          </miniInfos>;

            for (var i:uint = 0; i < xml.children().length(); i++)
            {
                var miniInfo:MiniInfo = new MiniInfo(xml.miniInfo[i].@id, 
                                                     xml.miniInfo[i].@text);

                miniInfo.x = 25;
                miniInfo.y = 25 + ((miniInfo.height + 25) * i);
                addChild(miniInfo);

                miniInfo.addEventListener(MouseEvent.CLICK, onMiniInfoClick);

            }// end for

        }// end function

        private function onMiniInfoClick(e:MouseEvent):void
        {
            loadBigInfo(MiniInfo(e.currentTarget).id);

        }// end function

        private function loadBigInfo(id:int):void
        {
            if (!_bigInfo)
            {
                _bigInfo = new BigInfo();
                _bigInfo.x = 150;
                _bigInfo.y = 25;
                addChild(_bigInfo);

            }// end if

            var urlVariables:URLVariables = new URLVariables();
            urlVariables.miniInfoID = id;

            var urlRequest:URLRequest = new URLRequest(_phpPath);
            urlRequest.method = URLRequestMethod.POST;
            urlRequest.data = urlVariables;

            var urlLoader:URLLoader = new URLLoader(urlRequest);
            urlLoader.addEventListener(Event.COMPLETE, onURLLoaderComplete);
            urlLoader.load(urlRequest);

        }// end function

        private function onURLLoaderComplete(e:Event):void
        {
            var urlLoader:URLLoader = URLLoader(e.currentTarget);

            var urlVariables:URLVariables = new URLVariables(urlLoader.data);

            _bigInfo.text = urlVariables.text;


        }// end function

    }// end class

}// end package

import flash.display.Sprite;
import flash.text.TextField;

internal class MiniInfo extends Sprite
{
    private var _id:int;
    private var _text:String
    private var _width:Number = 100;
    private var _height:Number = 25;

    override public function get width():Number { return _width } 
    override public function get height():Number { return _height }
    public function get id():int { return _id } 
    public function get text():String { return _text } 

    public function MiniInfo(id:int, text:String):void
    {
        _id = id;
        _text = text;

        graphics.beginFill(0xE1E1E1);
        graphics.drawRect(0, 0, _width, _height);
        graphics.endFill();

        var textField:TextField = new TextField();
        textField.x = textField.y = 5;
        textField.text = text;
        textField.mouseEnabled = false;
        addChild(textField);

    }// end function

}// end class

internal class BigInfo extends Sprite
{
    private var _width:Number = 100;
    private var _height:Number = 125;
    private var _textField:TextField;

    public function get text():String { return _textField.text } 
    public function set text(text:String):void { _textField.text = text; } 

    public function BigInfo()
    {
        graphics.beginFill(0xE1E1E1);
        graphics.drawRect(0, 0, _width, _height);
        graphics.endFill();

        _textField = new TextField();
        _textField.width = 90;
        _textField.wordWrap = true;
        _textField.x = _textField.y = 5;
        _textField.mouseEnabled = false;
        addChild(_textField);

    }// end function

}// end class

PHP

getBigInfo.php:

<?php

    if(!empty($_POST))
    {
        $bigInfos = array
                    (
                        array
                        (
                            'miniInfoID' => 1,
                            'text' => "This is the big info for mini info 1"
                        ),
                        array
                        (
                            'miniInfoID' => 2,
                            'text' => "This is the big info for mini info 2"
                        ),
                        array
                        (
                            'miniInfoID' => 3,
                            'text' => "This is the big info for mini info 3"
                        )
                    );

        $text;

        for($i = 0; $i < sizeof($bigInfos); $i++)
        {
            foreach($bigInfos as $item)
            {
                if($item['miniInfoID'] == (int)$_POST['miniInfoID'])
                {
                    $text = $item['text'];
                    break;
                }

            }// end foreach

            break;

        }// end for

        print "text=$text";

    }// end if

?>

The following is an image of the flash application running:

minibiginfos flash application

AS3 getting a textField.text on Click Event

4 Answers