Attempting a basic couchdb erlang view

Question

Im trying to do a simple view where it only emits documents where the id begins with "rating-". I dont seem to be able to call any "string:" functions at all in couchdb. Really not sure how to go about this... Every example I've have seen never compares part of value, always the entire value. In ecmascript i'd probably just do if (!doc._id.indexOf('rating-')). In this code below it complains one of the arguments supplied to split is invalid.

fun({Doc}) ->
    Id = proplists:get_value(<<"_id">>, Doc),
    DocChk = binary:split(Id, <<"-">>),
    case array:get(0, DocChk) of
      <<"rating-">> -> Emit(Id, nil)
    end
end.

I've had a few attempts, i've been trying out things in the Erlang shell and while I can occasionally not get a syntax error I can never get anything to run on couchdb. This the whole view i'm trying to adapt from ecmascript. As you can see... i'm still stuck on line 1 lol.

Map

function (doc) {
  if (doc._id.indexOf('rating-') !== 0) return;
  if (!doc.isValid) return;
  var nps;
  doc.results.forEach(function (r) {
    if (r.type === 'Nps') {
      nps = r;
    }
  });

  if (!nps) return;
  var result = { t: 1, d: 0, p: 0 };

  switch (nps.score) {
    case 10:
    case 9:
      result.p++;
      break;
    case 8:
    case 7:
      break;
    default:
      result.d++;
      break;
  }

  var week = new Date(doc.dateCaptured.year, doc.dateCaptured.month -1, doc.dateCaptured.day);
  week.setDate(week.getDate() - ((week.getDay() === 0 ? 7 : week.getDay())-1));

  emit(['week', doc.companyId, week.getFullYear(), week.getMonth()+1, week.getDate()], result);
  emit(['day', doc.companyId, doc.dateCaptured.year, doc.dateCaptured.month, doc.dateCaptured.day], result);
  emit(['month', doc.companyId, doc.dateCaptured.year, doc.dateCaptured.month], result);
  emit(['year', doc.companyId, doc.dateCaptured.year], result);

  emit(['week-bylocation', doc.companyId, doc.locationId, week.getFullYear(), week.getMonth()+1, week.getDate()], result);
  emit(['day-bylocation', doc.companyId, doc.locationId, doc.dateCaptured.year, doc.dateCaptured.month, doc.dateCaptured.day], result);
  emit(['month-bylocation', doc.companyId, doc.locationId, doc.dateCaptured.year, doc.dateCaptured.month], result);
  emit(['year-bylocation', doc.companyId, doc.locationId, doc.dateCaptured.year], result);

  emit(['week-bysource', doc.companyId, doc.sourceId, week.getFullYear(), week.getMonth()+1, week.getDate()], result);
  emit(['day-bysource', doc.companyId, doc.sourceId, doc.dateCaptured.year, doc.dateCaptured.month, doc.dateCaptured.day], result);
  emit(['month-bysource', doc.companyId, doc.sourceId, doc.dateCaptured.year, doc.dateCaptured.month], result);
  emit(['year-bysource', doc.companyId, doc.sourceId, doc.dateCaptured.year], result);
}

Reduce

function (keys, values, rereduce) {
  var result = { t: 0, p: 0, d: 0 };
  values.forEach(function (v) {
    result.t += v.t;
    result.p += v.p;
    result.d += v.d;
  });

  return result;
}

The performance of this view is just too slow. It wouldnt' be a problem incrementally but i have to seed index 6.3M rows and it would take about 12hours on 3 node cluster with a total of 12 cores. Definately cpu bound.

Edit

Thanks to Hynek I've been able to port my map function. I'm sure its very inefficient erlang but it seems to be about 30 times faster than its ecmascript counterpart.

fun({Doc}) ->
    case lists:keyfind(<<"_id">>, 1, Doc) of
        {_, <<"rating-", _/bytes>> = Id} -> 
          case couch_util:get_value(<<"isValid">>, Doc) of
            true -> 
              Results = proplists:get_value(<<"results">>, Doc),

              case lists:dropwhile(fun({R}) -> <<"Nps">> /= proplists:get_value(<<"type">>, R) end, Results) of
                [] -> ok;
                [{Nps} | _] -> 
                  Score = proplists:get_value(<<"score">>, Nps),
                  A = case Score of 
                    S when S > 8 -> [1, 0, 1];
                    S when S > 6 -> [0, 0, 1];
                    _ -> [0, 1, 1]
                  end,
                  CompanyId = proplists:get_value(<<"companyId">>, Doc),
                  LocationId = proplists:get_value(<<"locationId">>, Doc),
                  SourceId = proplists:get_value(<<"sourceId">>, Doc),
                  {DateCaptured} = proplists:get_value(<<"dateCaptured">>, Doc),
                  Year = proplists:get_value(<<"year">>, DateCaptured),
                  Month = proplists:get_value(<<"month">>, DateCaptured),
                  Day = proplists:get_value(<<"day">>, DateCaptured),
                  Emit([<<"year">>, CompanyId, Year], A),
                  Emit([<<"month">>, CompanyId, Year, Month], A),
                  Emit([<<"day">>, CompanyId, Year, Month, Day], A),

                  Emit([<<"year-bylocation">>, CompanyId, LocationId, Year], A),
                  Emit([<<"month-bylocation">>, CompanyId, LocationId, Year, Month], A),
                  Emit([<<"day-bylocation">>, CompanyId, LocationId, Year, Month, Day], A),

                  Emit([<<"year-bysource">>, CompanyId, SourceId, Year], A),
                  Emit([<<"month-bysource">>, CompanyId, SourceId, Year, Month], A),
                  Emit([<<"day-bysource">>, CompanyId, SourceId, Year, Month, Day], A)

              end;
            _ -> ok
          end;
        _ -> ok
    end
end.

Answer 1

The problem is that binary:split/2 result is not an array so you can't use array:get/2. Well, any seasoned Erlanger would write it like:

fun({Doc}) ->
    case lists:keyfind(<<"_id">>, 1, Doc) of
        {_, <<"rating-", _/bytes>> = Id} -> Emit(Id, nil);
        _ -> ok
    end
end.

Or if you feel less adventurous and would like to stick with recommended functions (probably a little bit slower):

fun({Doc}) ->
    case couch_util:get_value(<<"_id">>, Doc) of
        <<"rating-", _/bytes>> = Id -> Emit(Id, nil);
        _ -> ok
    end
end.

Edit: Meaning of = in Erlang needs more explanation. The equal sign in Erlang is more like equal in mathematics but not exactly.

1> X = 1.
1
2> 1 = X.
1
3> 1 = A = X.
1
4> A.
1
5> B = 1 = X.
1
6> B.
1
7> 1 = Z.
* 1: variable 'Z' is unbound
8> 2 = X.
** exception error: no match of right hand side value 1

What is going on there? The = sign has two distinct meanings and works closely with single assignment a.k.a. binding. First, it is a match operator in the expression. In place of any expression you can write a match expression:

 <Pattern> = <Expression>

It is the rightmost = in 3rd and 5th expression and sole = in other expressions in above example. After 1st expression, the X is already bound variable with value 1 and left of it is a pattern. The pattern can be a simple value or a variable or compound pattern. The variable could be bound or unbound. If the variable is not bound it binds to the value. If the variable is already bound match is checked. If used in the match expression match failure raises badmatch exception (class error) which is shown in a human-readable format in the shell as for 8th expression since I don't know R17-ish. Anyway, you can't change left and right sides of = operator in the match expression because the variable binding can only happen in pattern e.g. left operand of = as shown in 7th expression.

But you can use = in pattern as well and there it works as unification which is much more similar to equal in mathematics and there you can swap left and right freely. Experienced Erlangers are used to write patterns in the way I used in my example for a simple reason. If you read pattern you would like to know how the value should look like first and variable where you would like to bind the value as second as less important or something you need to know later in process of reading of the code.

Patterns don't appear only in match expressions but also in function clauses (actually {Doc} in the example is a pattern as well) and also in the case, try, receive expressions and in list comprehension generators. Pattern matching is one of the most powerful and cool features of Erlang language itself and in my example, I show only a glimpse of it. You can deconstruct complex data structures as tuples like {_, <<"rating-", _/bytes>> = Id}. You can pattern match binaries as shows this part <<"rating-", _/bytes>>.

Pattern matching of binaries uses Bit Syntax which is a powerful tool which makes implementing binary protocols in Erlang easy and fun but here I use it to make code much more efficient and clear of intention than ecmascript counterpart. Here I just clearly state that I'm interested of binary which starts with prefix rating- and continues anything (any binary a.k.a bytes) _/bytes. (I prefer using bytes and bits over binary and bitstring because it seems more expressing intention.)