Importing an empty CSV file in SAS

Question

I'm trying to import series of CSV files with a macro that loops thru all the files in the given folder.But, there are some empty CSV files in the folder which I would like to exclude from the loop. Is there any way in SAS to find CSV file size ?

PROC IMPORT OUT=&output
            DATAFILE= "&input"
            DBMS=CSV REPLACE;
     GETNAMES=YES;
     DATAROW=2;
        *GUESSINGROWS=32000;
RUN;

Thanks, Sam.

Answer 1

Here's away to do it in a datastep:

filename fileref 'c:\date.tmp';
data a;
infile fileref truncover;
fid=fopen('fileref');
Bytes=finfo(fid,'File Size (bytes)');                                                                                  
crdate=finfo(fid,'Create Time');
moddate=finfo(fid,'Last Modified');
input var1 $20.;
run;

Answer 2

%macro FileAttribs(filename);
  %local rc fid fidc Bytes;
   %let rc=%sysfunc(filename(onefile,&filename));
   %let fid=%sysfunc(fopen(&onefile));
   %let Bytes=%sysfunc(finfo(&fid,File Size (bytes)));
        %if &Bytes >0 %then %do;
                %put #####Size is > 0#####;
        %end;
        %else %do;
                %put #####Size is < 0#####;
        %end;
   %let fidc=%sysfunc(fclose(&fid));
   %let rc=%sysfunc(filename(onefile));
    %put NOTE: File size of &filename is &Bytes bytes;
%mend FileAttribs;

Answer 3

and here's another way to do it:

 %let filename =c:\date.tmp;                                                                                                       
 %let rc=%sysfunc(filename(onefile,&filename)); 

 %let fid=%sysfunc(fopen(&onefile));                                                                                                  
 %let Bytes=%sysfunc(finfo(&fid,File Size (bytes)));                           
 %let fidc=%sysfunc(fclose(&fid));                                                                                                    

 %put NOTE: File size of &filename is &Bytes bytes;