Structuring output for nodes in Neo4j

Question

I am new to neo4j and working on the Movie example to learn. I have been trying to do the classic shortest path between Kevin Bacon and Meg Ryan query but also change the output of the columns. The query below has two different approaches. The first column I don't understand why it doesn't work. So I have two questions.

What is the best way to output properties from nodes dependant on the type of node in a path?
How can I mix up the output to achieve the output as Actor Name, Relationship, Movie Name, Relationship Actor Name. I can do this when not using a path but struggling when processing a path.

Query with example return attempts:

MATCH p=shortestPath(
    (bacon:Person {name:"Kevin Bacon"})-[*]-(meg:Person {name:"Meg Ryan"})
)

    RETURN 
        [n in nodes(p) | case when labels(n) = 'Person' then n.name when labels(n) = 'Movie' then n.title end ],
        [a in nodes(p) where has(a.name) | a.name],
        [b in nodes(p) where has(b.title) | b.title]

The output from this is (apologies no kudos to post pictures)

null,null,null,null
Kevin Bacon, Tom Cruise, Meg Ryan
A Few Good Men, Top Gun

preferred output Kevin Bacon,A Few Good Men,Tom Cruise, Top Gun,Meg Ryan

Nicole White Nicole White · Accepted Answer · 2014-10-24T12:39:25

A hard-coded solution is to use COALESCE():

MATCH p=shortestPath(
    (bacon:Person {name:"Kevin Bacon"})-[*]-(meg:Person {name:"Meg Ryan"})
)    
RETURN EXTRACT(x IN NODES(p) | COALESCE(x.name, x.title))

Output:

Kevin Bacon, A Few Good Men, Tom Cruise, Top Gun, Meg Ryan

But this only works because we know that Movie nodes don't have a name property. If they did for some reason...

MATCH (m:Movie) SET m.name = "Something Unrelated"

Then the above would fail, and we would get:

Kevin Bacon, Something Unrelated, Tom Cruise, Something Unrelated, Meg Ryan

So a more general solution is:

MATCH p=shortestPath(
    (bacon:Person {name:"Kevin Bacon"})-[*]-(meg:Person {name:"Meg Ryan"})
)    
RETURN EXTRACT(
    x IN NODES(p) | CASE WHEN x:Person THEN x.name
                         WHEN x:Movie  THEN x.title
                    END
)

Your attempt of

[n in nodes(p) | case when labels(n) = 'Person' then n.name when labels(n) = 'Movie' then n.title end ]

was really close, but LABELS() returns a collection, so you need to check that a string is IN LABELS(), not that LABELS() is equal to a string.

Structuring output for nodes in Neo4j

1 Answers