Transfering Actionscript 2 code to Actionscript 3

Question

I started a few years back with actionscript 3 when I got out of school and the first real job I had, I had to get into actionscript 2. So after about three years of coding things into actionscript 2, I have forgotten actionscript 3. This is really mind numbing mostly because all the tutorials and etc I keep finding uses classes and public functions and the etc.

The whole idea of this a basic slide show that we can run as a swf file or exe. Most of the code is gotoAndStop or gotoAndPlay commands. The toggles and navigation mebu has driven me a bit batty becuase of the strict class features of as3.

I have one target menu that comes up when the swf file begins. You click it to go to the next step or to go advance to additional steps. This is the navmenu as refeered to the code below. A button (called "menu") toggles this menu's visibily when clicked. A prev_btn and next_btn are on adjacent sides of the menu button that will allow it to move to the next frame label or preious frame label.

Then at any time, you could hit the menu button and bring up the main menu. From here you could move to varous stages of the timeline.

So I can't figure out how to do this with keeping the same graphics and ease of use.

//fscommands that set up the exit and fullscreen functions
fscommand("fullscreen", "true");
fscommand("allowscale", "false");
fscommand("showmenu", false);

navmenu._visible=0;
menu_btn.onRelease=function()
    {
        navmenu._visible=1;
    }

//******************Initialization When Program first starts*********************

_global.initialize=function(){
    gotoAndStop("sc1-step0-0");
};


exit_btn.onRelease = function() {
    fscommand("quit");
};


reset_btn.onRelease = function() {
    initialize();
};


callouts_btn.onRelease = function(){
    if (callouts_mc._visible == true) {
        callouts_mc._visible = false;
    }else{
        callouts_mc._visible = true;
    }
};


highlight_btn.onRelease=function(){
    ToggleHighlights();
}


function ToggleHighlights(){
    showHighlights = !showHighlights;
    if(showHighlights){
        highlights_mc.gotoAndPlay("show");
    }
    else{
        highlights_mc.gotoAndPlay("hide");
    }
}

function ShowHighlights(){
    if( showHighlights ){
        highlights_mc.gotoAndPlay("show");
    }
    else{
        highlights_mc.gotoAndPlay("hide");
    }
}

//*******Start Program**********

initialize();

prev_btn.onRelease=function(){
    gotoAndPlay("sc1-step1-0");
}

next_btn.onRelease=function(){
    gotoAndPlay("sc1-step3-0");
}

The function ShowHighlights() is not used, but I translated your entire code. — helloflash

helloflash helloflash · Accepted Answer · 2014-07-26T08:47:18

Translated into AS3, the code you shows here gives this:

stage.displayState = StageDisplayState.FULL_SCREEN;
stage.scaleMode = StageScaleMode.NO_SCALE;
stage.showDefaultContextMenu = false;

var showHighlights:Boolean = false;
navmenu.visible = false;

menu_btn.addEventListener(MouseEvent.MOUSE_UP, menuVisible);

function menuVisible(e:MouseEvent):void {
    navmenu.visible = true;
}

exit_btn.addEventListener(MouseEvent.MOUSE_UP, toQuit);

function toQuit(e:MouseEvent):void {
    fscommand("quit");
}

reset_btn.addEventListener(MouseEvent.MOUSE_UP, init);

function init(e:MouseEvent):void {
    initialize();
}

function initialize():void {
    gotoAndStop("sc1-step0-0");
}

callouts_btn.addEventListener(MouseEvent.MOUSE_UP, callouts_mcVisible);

function callouts_mcVisible(e:MouseEvent):void {
    callouts_mc.visible = !callouts_mc.visible;
}

highlight_btn.addEventListener(MouseEvent.MOUSE_UP, ToggleHighlights);

function ToggleHighlights(e:MouseEvent):void {
    showHighlights = !showHighlights;
    if (showHighlights)
    {
        highlights_mc.gotoAndPlay("show");
    }
    else
    {
        highlights_mc.gotoAndPlay("hide");
    }
}

function ShowHighlights(e:MouseEvent) {
    if (showHighlights)
    {
        highlights_mc.gotoAndPlay("show");
    }
    else
    {
        highlights_mc.gotoAndPlay("hide");
    }
}

//*******Start Program**********

initialize();

prev_btn.addEventListener(MouseEvent.MOUSE_UP, gotoPrev);

function gotoPrev(e:MouseEvent):void {
    gotoAndPlay("sc1-step1-0");
}

next_btn.addEventListener(MouseEvent.MOUSE_UP, gotoNext);

function gotoNext(e:MouseEvent):void {
    gotoAndPlay("sc1-step3-0");
}

Transfering Actionscript 2 code to Actionscript 3

1 Answers