Extending list pseudo methods in Specman

Question

Is there a way I could extend the given pseudo methods for lists in e, to add some specific implementation?

Thanks

Answer 1

"pseudo method" is not really a method, it just looks as if it was. So it cannot be extended with "is also/only/etc".

but you can define any "pseudo method" of your own, using macro.

for example - pseudo method that adds only even items - (do note the \ before the () )

define <my_pseudo_method'action> "<input1'exp>.add_if_even\(<input2'num>\)" 
      as computed  {
result = append("if ", <input2'num>, " %2 == 0 then { ",   <input1'exp>, ".add(", <input2'num>, ")};");
}

then can be called from another file -

extend sys {
    run() is also {
        var my_list : list of int;
        for i from 0 to 10 {
            my_list.add_if_even(i);
        };
        print my_list;
    };
};

Answer 2

Using a macro, you can even "override" an existing pseudo-method. For example, let's say you want to modify add() so that it will add an element to the list only if it is not already in the list. (In other words, you want to keep all elements in the list unique). You can do something like this:

define <my_add'action> "<list'exp>.add\(<exp>\)" as {
    if not <list'exp>.has(it == <exp>) then {
        var new_size<?>: int = <list'exp>.size() + 1;
        <list'exp>.resize(new_size<?>, TRUE, <exp>, TRUE);
    };
};

Note that I use another pseudo-method here - resize() - to implement the actual addition of the new element to the list. If I tried to use the add() pseudo-method itself, it wouldn't work, and would lead to an infinite recursion. This is because add() used inside the macro would again call the macro itself, and not the pre-defined pseudo-method being overridden.

Answer 3

You can also use templates to add/modify list pseudo-methods. e.g.

<'
template struct MyList of (<T1'type>) {
   items: list of <T1'type>;
   keep soft items.size()==10;
   pop_index(i:int):<T1'type> is {
      result = items[i];
      items.delete(i);     
   };
};
extend sys {
   list1: MyList of (byte);
   // somehwere
   var foo:= list1.pop_index(3);
};
'>