Cons element to list vs cons list to element in Scheme

11
votes

What's the difference between using cons to combine an element to a list and using cons to combine a list to an element in scheme?

Furthermore, how exactly does cons work? Does it add element to the end of the list or the beginning?

Thanks!

1
listlispschemecons
@ÓscarLópez's answer explains this pretty well. It's helpful to realize that in the Lisp family of languages it's not quite right to think of cons as a list operation. Lisp languages typically have cons cells as genuine datatypes and then implement lists as intensional datatypes. The things that we call lists are lists by convention. I mentioned this in an earlier answer while describing how we can often cons cells to implement lists, but how we can also cons cells to implement other structures, such as trees. – Joshua Taylor
@JoshuaTaylor Page Not found. – Han Qiu
@hanQiu I guess that question got deleted. But there's a section in SO documentation now that covers the same idea: lists as a convention – Joshua Taylor
That documentation also got deleted :( – Óscar López

1 Answers

27
votes

The primitive cons simply sticks together two things, the fact that some of those things are considered lists is incidental. For instance, this works and creates a pair (also known as a cons cell):

(cons 1 2)
=> '(1 . 2)     ; a pair

Now, if the second argument to cons happens to be a list, then the result will be a new list, and the first argument to cons will be added at the head of the old list. In other words: to create a list you need a list, even if it's empty:

(cons 1 '(2 3))
=> '(1 2 3)     ; a list

(cons 1 (cons 2 '()))
=> '(1 2)       ; a list

(cons 1 '())
=> '(1)         ; a list

But if the second argument to cons is not a list, then the result will be just a pair, or an improper list, meaning that it doesn't end in '() as it should to be considered a list:

(cons '(1 2) 3)
=> '((1 2) . 3) ; a pair, not a list

(cons 1 (cons 2 3))
=> '(1 2 . 3)   ; an improper list

Just to clarify, you can't use cons to add elements at the end of a list. The usual way to build a list is going from right-to-left, adding elements in reverse at the head position - say you want to build the list '(1 2 3), then you have to cons the elements in the order 3 2 1:

(cons 3 '())                   ; list is '(3)
(cons 2 (cons 3 '()))          ; list is '(2 3)
(cons 1 (cons 2 (cons 3 '()))) ; list is '(1 2 3)

For those rare occasions where you need to add one element at the end (and believe me, doing so generally means that you're thinking the algorithm wrong) you can use append, which receives two lists as arguments:

(append '(1 2 3) '(4))
=> '(1 2 3 4)