Communicating with desktop Air App from device

Question

i've been looking around for some examples on how this is done- but the only information i can find doesnt really make it clear to me.

im hoping someone here can possible lend some insight.

i currently have an air app the i made some time ago. The air app stops on Frame 3 and I have to use a mouse click to proceed. What i want to do is advance to the next frame when i click a btn on a html page loaded on a device(phone/tablet). The Air App itself will be running all the time.

I've got a server setup so i can access the html button from my device (local network).

I've also implemented this http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/net/Socket.html#includeExamplesSummary to see how it interacts with my server. When i run the air app i can see it calling the server and the air app does print some results from the server in the debugger output. But really, this isnt what i want to do. It just demonstrates that there is some connectivity happening. but the flow is all wrong.

So my question is. can anyone give me some details on how to trigger a frame in an Air App from another device within the same network? The other device doesnt need to have any flash on it. just a simple html button will do.

thanks

So are you able to receive a message in your AIR app ok? Just need help changing the frame? — user1901867
well, the air app only hits the server when i run the debug on the air app. it's not really the flow that i need. but it does demonstrate that there is some sort of connectivity happening. What needs to happen is that air app listens for a connection on the server using a port and then somehow triggering all this from the html page. — flash_help

Tom Makin Tom Makin · Accepted Answer · 2013-04-15T22:40:14

I'd say you have two possible routes here.

Create a script on your server to initiate a connection to your air app. For example using php and a socket, the link would be something like http://myserver/nextslide.php which could then connect to your air app on a TCP port of your choice. There are loads of options here depending on your server and what scripting languages you have available.
Setup your air app as a web server to allow your browser to send an HTTP request directly. For example there is a very simple air HTTP server here (which is not much more than a socket server which closes the connection at the end of each request). You could still serve your html from the main web server as you currently do, but from the HTTP server in the air app you just need to move onto the next slide when the relevant URI is found in the HTTP header. If you only need it to work within your local network this is what I would go for.

Example as3 code for option 2 above, tested using an air projector with FlashDevelop:

package 
{
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.events.ServerSocketConnectEvent;
    import flash.net.ServerSocket;
    import flash.net.Socket;
    import flash.utils.ByteArray;

    public class Main extends Sprite 
    {
        private var serverSocket:ServerSocket;
        private var port:int = 8080;

        public function Main():void 
        {
            listen();
        }

        private function listen():void
        {
            try
            {
                serverSocket = new ServerSocket();
                serverSocket.addEventListener(Event.CONNECT, socketConnectHandler);
                serverSocket.bind(port);
                serverSocket.listen();
                trace("Listening on port " + port + "...\n");
            }
            catch (error:Error)
            {
                trace("Failed to open server socket");
            }
        }

        private function socketConnectHandler(event:ServerSocketConnectEvent):void
        {
            var socket:Socket = event.socket;
            socket.addEventListener(ProgressEvent.SOCKET_DATA, socketDataHandler);
        }

        private function socketDataHandler(event:ProgressEvent):void
        {
            try
            {
                var socket:Socket = event.target as Socket;
                var bytes:ByteArray = new ByteArray();
                socket.readBytes(bytes);
                var request:String = "" + bytes;
                trace(request);
                var url:String = request.substring(4, request.indexOf("HTTP/") - 1);

                socket.writeUTFBytes("HTTP/1.1 200 OK\n");
                socket.writeUTFBytes("Content-Type: text/plain\n\n");

                if (url == "/next")
                {
                    socket.writeUTFBytes("next frame triggered");

                    var someMovie:MovieClip = new MovieClip(); //define this as a reference to the movie clip you want to control
                    someMovie.nextFrame();
                }
                else
                {
                    socket.writeUTFBytes("The url is " + url);
                }

                socket.flush();
                socket.close();
            }
            catch (error:Error)
            {
                trace(error);
            }
        }
    }
}

Communicating with desktop Air App from device

1 Answers