connection between Flex and FLash

Question

I am working on a project, which is based on two main parts, the first part is done by Flex, and second one is a flash professional project, contains PROJECTNAME.fla and PROJECTNAME.as files. My question is how we can set some parameters in .fla project (e.g. usernames, user's images) from flex part. I explain main procedure by following;

Connect to server by flex part and get user's status
run .swf created by a flash professional project as described above
set some parameters in .swf file.

I have googled a lot, and I did not find any solution. (there was some solution that converts symbol to flex component, since it works for converting a single symbol). Any Idea will be appreciated.

Are you saying that the flex "shell" loads up the flash published swf? — neil manuell
Yes, my goal is that. As I said for a single symbole that is possible, since we can create a .swc file and simply use it in flex project, but in my case I need some advice, thanks. — csuo
Maybe you need to use SWFLoader? help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/mx/… — JeffryHouser

fsbmain fsbmain · Accepted Answer · 2013-02-02T12:14:48

There are several possibilities to pass the params from one swf (flex in your case) to another runtime loaded fla.swf:

1.Pass through the loading query params:

code in flex.swf:

    public function astest()
    {
        var loader:Loader = new Loader();
        addChild(loader);
        loader.load( new URLRequest("astest1.swf?param1=value1&param2=value2"));
    }

access params from fla.swf:

public function astest1()
{
    if(stage)
        onAdded();
    else
        addEventListener(Event.ADDED_TO_STAGE, onAdded);
}

protected function onAdded(event:Event = null):void
{
    //root.loaderInfo.parameters - params of this swf file
    //stage.loaderInfo.parameters - params of core swf file
    var params:Object = root.loaderInfo.parameters;
    for (var param:String in params)
        trace(param,"=",params[param]);
}

output:

param2 = value2
param1 = value1

lacks of this method:

-one time usage, you can pass params only one time when loading
-the second swf must be runtime loaded by url, you can't embed it (or one of the class withing it) for example.

2.Runtime communication through the events
I recommend to use this method, it hasn't lacks of previous one.
Example of using stage as the global common dispatcher.

flex.swf:

    public function astest()
    {
        addEventListener("ready", onReady);
        var loader:Loader = new Loader();
        addChild(loader);
        loader.load( new URLRequest("astest1.swf"));
    }

    protected function onReady(event:Event):void
    {
        sendParams("param1=value1&param2=value2");
    }

    protected function sendParams(params:String):void
    {
        stage.dispatchEvent(new DataEvent("params", false, false, params));
    }

fla.swf:

public function astest1()
{
    if(stage)
        onAdded();
    else
        addEventListener(Event.ADDED_TO_STAGE, onAdded);
}

protected function onAdded(event:Event = null):void
{
    stage.addEventListener("params", onParams);
    //fire event with bubbling that anables handling it in the parent swf
    dispatchEvent(new Event("ready", true));
}

protected function onParams(event:DataEvent):void
{
    var data:String = event.data;
    trace(data);
}

output:

param1=value1&param2=value2

with this approach you send as many params as you need, you alsa can create custom event to pass Object parameters but in this case both project must have this cusom event in there source paths.

connection between Flex and FLash

1 Answers