(g)Vim -> show 4 spaces, but save 2 spaces (tabs)

Question

Is it possible to open files that are indented with 2 spaces, but show me 4 space indentation, and when I make 4 spaces, it saves in a 2 space format?

Edit

It turns out I also need to be able to ensure that it works if the file has a mix of tabs, 2 spaces, and 4 spaces.

Edit 2

So, here is my current solution. I'm having to remap my (originally mapped to :w) so that I can place my cursor back where it was (and give me one "history back" as far as cursor positions when I do a save. Is there a way to do this without affecting cursor position (and not adding the substitution to the history, either)?

function! s:ShimSpaces()
    nunmap <C-S>
    nmap <C-S> ms``mt:w<Cr>`t`s
    augroup SeoTabs
        autocmd!
        autocmd BufReadPost,BufWritePost * set tabstop=4
        autocmd BufReadPost,BufWritePost * %substitute/^ \+/&&/e
        autocmd BufReadPost              * %substitute/ \+$//e
        autocmd BufWritePre              * %substitute/^\( \+\)\1/\1/e
        autocmd BufWritePre              * set tabstop=2
        autocmd BufWritePre              * retab
    augroup END
endfunction
command! -n=0 -bar ShimSpaces :call s:ShimSpaces()

I hope this is a possible solution for you. stackoverflow.com/questions/5217058/… — Sudip Kafle
Thanks for the attempt, Sudip. Not quite. I'm thinking that Ingo may have the right idea below. (Just need to try it out.) Thanks for the reply! — Mr Mikkél

Ingo Karkat Ingo Karkat · Accepted Answer · 2013-01-25T07:38:44

^{This is the opposite of what was asked here.}

The help has an example for a similar use case of different tab widths, see :help retab-example.

Adapting that to doubling / halving spaces:

:augroup AdaptIndent
    :autocmd!
    :autocmd BufReadPost,BufWritePost  * %substitute/^ \+/&&/e
    :autocmd BufWritePre               * %substitute/^\( \+\)\1/\1/e
:augroup END

With *, this will affect all opened files. To restrict this to certain files, see :help autocmd-patterns.

Edit: With the :augroup wrapping, this can be turned off again via :autocmd! AdaptIndent. This way, you can easily toggle this on / off. For ease of use, I'd put this in a function and define a custom command calling it.

(g)Vim -> show 4 spaces, but save 2 spaces (tabs)

1 Answers