Send Arduino data via a Wi-Fi shield to a specific IP address on the LAN

Question

I'm attempting to send sensor data from an Arduino Uno via a Copperhead Wi-Fi shield to a specific IP address and port on a LAN.

I can get the Copperhead Wi-Fi Server example sketch to work (pasted below). However, I'm not interested in responding to server requests via HTML. All I'm interested in is setting up a socket-like connection and sending data via TCP or UDP to IP address 192.168.0.3, port 1234.

I'm sure there is an easy solution to this, but as I am new to Arduino and my attempts to find a solution have been unsuccessful.

#include <WiServer.h>
#define WIRELESS_MODE_INFRA 1
#define WIRELESS_MODE_ADHOC 2

// Wireless configuration parameters ----------------------------------------
unsigned char local_ip[] = {192,168,0,2};   // IP address of WiShield
unsigned char gateway_ip[] = {192,168,0,1}; // router or gateway IP address
unsigned char subnet_mask[] = {255,255,255,0};  // subnet mask for the local network
const prog_char ssid[] PROGMEM = {"WiFi_AP"};       // max 32 bytes

unsigned char security_type = 0;    // 0 - open; 1 - WEP; 2 - WPA; 3 - WPA2

// WPA/WPA2 passphrase
const prog_char security_passphrase[] PROGMEM = {"12345678"};   // max 64 characters

// WEP 128-bit keys
// sample HEX keys
prog_uchar wep_keys[] PROGMEM = { 0x01, 0x02, 0x03, 0x04, 0x05, 0x06, 0x07, 0x08, 0x09,     0x0a, 0x0b, 0x0c, 0x0d, // Key 0
              0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, // Key 1
              0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, // Key 2
              0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00  // Key 3
            };

// Setup the wireless mode
// Infrastructure - connect to AP
// Adhoc - connect to another Wi-Fi device
unsigned char wireless_mode = WIRELESS_MODE_INFRA;

unsigned char ssid_len;
unsigned char security_passphrase_len;
// End of wireless configuration parameters ----------------------------------------


// This is our page serving function that generates web pages
boolean sendMyPage(char* URL) {

    // Check if the requested URL matches "/"
    if (strcmp(URL, "/") == 0) {
        // Use WiServer's print and println functions to write out the page content
        WiServer.print("<html>");
        WiServer.print("Hello World");
        WiServer.print("</html>");

        // URL was recognized
        return true;
    }
    // URL not found
    return false;
}


void setup() {
    // Initialize WiServer and have it use the sendMyPage function to serve pages
    WiServer.init(sendMyPage);

    // Enable Serial output and ask WiServer to generate log messages (optional)
    Serial.begin(57600);
    WiServer.enableVerboseMode(true);
}

void loop(){
    // Run WiServer
    WiServer.server_task();

    delay(10);
}

crowbent crowbent · Accepted Answer · 2012-09-05T18:33:06

Looks like you are using the WiShield library. There should be an examples folder in the WiShield download with a SocketApp and UDPApp example. This is a good place to start.

A few things I learned while making a UDP app.

You may have to edit some #defines (e.g. APP_UDPAPP in apps-conf.h, UIP_CONF_UDP in uip-conf.h) before recompiling your app.
If you are doing a UDP app, keep in mind that you have a limited receive buffer (UIP_CONF_BUFFER_SIZE in uip-conf.h sets it to 400). My router was sending out a UDP broadcast XML message that was ~700 bytes which caused this buffer to overflow and over write other data. I don't think TCP will have this problem because it will negotiate a MSS that won't overrun the buffer.

In the end I made changes to the handle_connection() function in the UDPapp example. Below is a snippet (with uip_ipaddr set to 255.255.255.255).

void send_state(void) {
    sprintf((char*)uip_appdata, "state %ld %ld %ld %c %d", 
    clock_time(), 
    state.sensors.ping[0].cm,
    state.sensors.ping[1].cm,
    state.actuators.chassis.direction,
    state.actuators.chassis.speed);
    uip_send(uip_appdata, strlen((char*)uip_appdata));
}

void send_beacon(void) {
    if(timer_expired(&beacon_timer)) {
        timer_reset(&beacon_timer);
        sprintf((char*)uip_appdata, "beacon %ld", clock_time());
        uip_send(uip_appdata, strlen((char*)uip_appdata));
        uip_log("beacon sent");
    }
}

boolean data_or_poll(void) {
    return (uip_newdata() || uip_poll());
}

static PT_THREAD(handle_connection(void)) {
    PT_BEGIN(&s.pt);
    PT_WAIT_UNTIL(&s.pt, data_or_poll());
    if(uip_newdata()) {
        uip_flags &= (~UIP_NEWDATA);
        send_state();
    } else if (uip_poll()) {
        uip_flags &= (~UIP_POLL);
        send_beacon();
    }

    PT_END(&s.pt);
}

Send Arduino data via a Wi-Fi shield to a specific IP address on the LAN

2 Answers