Is there any haskell function to concatenate list with separator?

142
votes

Is there a function to concatenate elements of a list with a separator? For example:

> foobar " " ["is","there","such","a","function","?"]
["is there such a function ?"]

Thanks for any reply!

5
listhaskellconcat
I know lmgtfy answers are bad, but it's worth noting that a search for "String -> [String] -> String" on hoogle gets just what you want. haskell.org/hoogle – sigfpe
for joining with spaces you also have unwords – epsilonhalbe
@sigfpe Side comment: You would have to look for [String] -> String -> String in case that the other way returns no answer, right? – Lay González
@LayGonzález The search is up to permutations. For instance searching for [a] -> (a -> b) -> [b] returns map as its first result. – gallais

5 Answers

243
votes

Yes, there is:

Prelude> import Data.List
Prelude Data.List> intercalate " " ["is","there","such","a","function","?"]
"is there such a function ?"

intersperse is a bit more general:

Prelude> import Data.List
Prelude Data.List> concat (intersperse " " ["is","there","such","a","function","?"])
"is there such a function ?"

Also, for the specific case where you want to join with a space character, there is unwords:

Prelude> unwords ["is","there","such","a","function","?"]
"is there such a function ?"

unlines works similarly, only that the strings are imploded using the newline character and that a newline character is also added to the end. (This makes it useful for serializing text files, which must per POSIX standard end with a trailing newline)

4
votes

It's not hard to write one-liner using foldr

join sep xs = foldr (\a b-> a ++ if b=="" then b else sep ++ b) "" xs
join " " ["is","there","such","a","function","?"]
3
votes
joinBy sep cont = drop (length sep) $ concat $ map (\w -> sep ++ w) cont
3
votes

Some other ideas of implementations of intersperse and intercalate, if someone is interested:

myIntersperse :: a -> [a] -> [a]
myIntersperse _ [] = []
myIntersperse e xs = init $ xs >>= (:[e])

myIntercalate :: [a] -> [[a]] -> [a]
myIntercalate e xs = concat $ myIntersperse e xs

xs >>= f is equivalent to concat (map f xs).

2
votes

If you wanted to write your own versions of intercalate and intersperse:

intercalate :: [a] -> [[a]] -> [a]
intercalate s [] = []
intercalate s [x] = x
intercalate s (x:xs) = x ++ s ++ (intercalate s xs)

intersperse :: a -> [a] -> [a]
intersperse s [] = []
intersperse s [x] = [x]
intersperse s (x:xs) = x : s : (intersperse s xs)