Using put and proc format to create a new column in SAS

Question

I have a following code:

  visitnum = put(visitn,visitnumber.);

which is directed to

  proc format;
   value visitnumber
  'Screening Assessment' = 1
  'Treatment Visit - Day 1' = 2
  'Treatment Visit - Day 7' = 3
  'Treatment Visit - Day 14/15' = 4
  'Follow-Up Visit - Day 28' = 5
 run;

However when I output the 'visitnum' variable, it gives the 'Treatmen' as the output for the matching columns.

Are you sure that your code is correct? If you are converting numeric to character, the equals signs should be flipped. e.g. 1 = 'Screening Assessment' — Stu Sztukowski
I understand what you mean however in this case it really is character to numeric encoding. — AishwaryaKulkarni
Note if you really want to move from character to numeric you need to use an INFORMAT, since you are using a FORMAT it is still character to character. — Tom
What is the length of the VISITN variable? Did you define the length of the new VISITNUM variable before the assignment statement? You might want to include an other category in your format definition to set the value to return when the input value is not on the list. — Tom

Stu Sztukowski Stu Sztukowski · Accepted Answer · 2021-10-22T15:07:25

If this is character to numeric, you need to use an informat rather than a format.

proc format;
   invalue visitnumber
      'Screening Assessment'        = 1
      'Treatment Visit - Day 1'     = 2
      'Treatment Visit - Day 7'     = 3
      'Treatment Visit - Day 14/15' = 4
      'Follow-Up Visit - Day 28'    = 5
  ;
 run;

Example:

data foo;
    length visitn $27.;

    do visitn = 'Screening Assessment'
              , 'Treatment Visit - Day 1'
              , 'Treatment Visit - Day 7'
              , 'Treatment Visit - Day 14/15'
              , 'Follow-Up Visit - Day 28'
    ;
        visitnum = input(visitn, visitnumber.);
        output;
    end;
run;

Output:

visitn                        visitnum
Screening Assessment          1
Treatment Visit - Day 1       2
Treatment Visit - Day 7       3
Treatment Visit - Day 14/15   4
Follow-Up Visit - Day 28      5

Using put and proc format to create a new column in SAS

2 Answers