How to set the paper size using the WinSpool API?

Question

I can't use the XPS API since the program has to be able to print on Windows XP.

I'm trying to set the paper size from Letter to A4 using WinSpool.

This is my test code:

var
  H          : THandle;
  I          : TBytes;
  Info       : PPrinterInfo2;
  NeededSize : DWORD;
  DevMode    : PDeviceMode;
  PD         : TPrinterDefaults;
begin
  PD.pDatatype     := nil;
  PD.pDevMode      := nil;
  PD.DesiredAccess := PRINTER_ACCESS_ADMINISTER;
  if not OpenPrinter('Brother HL-5350DN series Printer', H, @PD) then begin
    raise Exception.Create('OpenPrinter error: ' + SysErrorMessage(GetLastError));
  end;
  try
    Assert(not GetPrinter(H, 2, nil, 0, @NeededSize));
    SetLength(I, NeededSize);
    Info := @I[0];
    if not GetPrinter(H, 2, Info, NeededSize, @NeededSize) then begin
      raise Exception.Create('GetPrinter error: ' + SysErrorMessage(GetLastError));
    end;
    DevMode             := Info.pDevMode;
    DevMode.dmFields    := DevMode.dmFields or DM_PAPERSIZE;
    DevMode.dmPaperSize := DMPAPER_A4;
    Info.pSecurityDescriptor := nil; // According to MSDN it has to be niled if we're not going to change it.

    if not SetPrinter(H, 2, Info, 0) then begin
      raise Exception.Create('SetPrinter error: ' + SysErrorMessage(GetLastError));
    end;
  finally
    ClosePrinter(H);
  end;
  TPrintDialog.Create(Self).Execute; // This is just so I can check the paper size
end;

I have two problems related to access rights.

If I set PD.DesiredAccess to PRINTER_ACCESS_ADMINISTER the GetPrinter call fails, I guess this is due to UAC.

If I set it to PRINTER_ACCESS_USE the GetPrinter call succeeds and the Info structure is fine, but the call to SetPrinter fails.

Interestingly enough when I ignore the Result of SetPrinter the print dialog reports A4 as the printer size even though SetPrinter fails.

Am I doing it completly wrong and it is enough to pass a correctly setup up PDeviceMode to OpenPrinter? (I actually came up with this after writing this question :-)

Another question regarding the VCL:

If I use the Printers unit how do I know how big the buffers have to be that get passed as parameters to the TPrinter.GetPrinter method?

Background:

The system is: Windows 7 Professional 64-Bit English with English locale.

I'm trying to print to A4 paper on a network printer (Brother HL-5350DN).

I have set all printer settings in the control panel to A4 paper, but the Delphi 2009 program I'm writing still gets the paper dimensions for US Letter.

In other words: The Delphi program doesn't respect the default settings of the printer spooler.

If I run a TPrinterDialog first and select the correct paper size from there manually (in the advanced printer settings) everything is fine.

The program has to run without any UI, so I have to solve this programmatically or preferably the program should just respect the default Windows printer spooler settings.

Maybe I have missed some imporant setting?

@David: There is no PageFormat setting in TPrinter, the only way I can see is to use TPrinter.GetPrinter and TPrinter.SetPrinter. How do I know how much space to allocated for the arguments of TPrinter.GetPrinter? — Jens Mühlenhoff
What are you actually trying to do here? Surely the printer knows what size the paper is. The user selects which tray they want from the printer prefs dialog. You can't change the paper size in code! It might help us if you told us the whole story rather than giving just a window into one tiny corner of your problem. — David Heffernan
I have added some more background information to the question. — Jens Mühlenhoff
It sounds to me like the printer preferences aren't set correctly. I'd be looking to fix that rather than trying to code around it. — David Heffernan
@Jens - The VCL does not fill in the 'driver' and 'port' fields (unless running on W9x) and it would seem you already know the printer name, reserve a character for 'driver' and 'port' and the length of the printer name for 'device'. If you don't know the printer name, it is at most 539 characters. You can even hack Printer.Printers.Objects[#] to a TPrinterDevice (=class Driver,Device,Port: string; end;) to be sure. — Sertac Akyuz

Alex Alex · Accepted Answer · 2011-10-18T08:47:15

try this guys it work for me

uses WinSpool,Windows,System;

procedure SetPrinterInfo(APrinterName: PChar);
var

  HPrinter : THandle;
  InfoSize,
  BytesNeeded: Cardinal;
  DevMode    : PDeviceMode;
  PI2: PPrinterInfo2;
  PrinterDefaults: TPrinterDefaults;

begin
  with PrinterDefaults do
  begin
    DesiredAccess := PRINTER_ACCESS_USE;
    pDatatype := nil;
    pDevMode := nil;
  end;
  if OpenPrinter(APrinterName, HPrinter, @PrinterDefaults) then
  try
    SetLastError(0);
    //Determine the number of bytes to allocate for the PRINTER_INFO_2 construct...
    if not GetPrinter(HPrinter, 2, nil, 0, @BytesNeeded) then
    begin
      //Allocate memory space for the PRINTER_INFO_2 pointer (PrinterInfo2)...
      PI2 := AllocMem(BytesNeeded);
      try
        InfoSize := SizeOf(TPrinterInfo2);
        if GetPrinter(HPrinter, 2, PI2, BytesNeeded, @BytesNeeded) then
        begin
          DevMode := PI2.pDevMode;
          DevMode.dmFields := DevMode.dmFields or DM_PAPERSIZE;
          DevMode.dmPaperSize := DMPAPER_A4;
          PI2.pSecurityDescriptor := nil;
          // Apply settings to the printer
          if DocumentProperties(0, hPrinter, APrinterName, PI2.pDevMode^,
                                PI2.pDevMode^, DM_IN_BUFFER or DM_OUT_BUFFER) = IDOK then
          begin
            SetPrinter(HPrinter, 2, PI2, 0);  // Ignore the result of this call...
          end;
        end;
      finally
        FreeMem(PI2, BytesNeeded);
      end;
    end;
  finally
    ClosePrinter(HPrinter);
  end;
end;

How to set the paper size using the WinSpool API?

2 Answers