Running aws instance with connection using terraform

Question

resource "aws_instance" "appserver1" {
  ami             = var.imageid
  instance_type   = var.instancetype
  key_name        = var.key
  security_groups = [aws_security_group.allow_all.name]

  connection {
    user        = "ubuntu"
    private_key = file(var.privatekeypath)
  }

  provisioner "remote-exec" {
    inline = [
      "sudo apt-get update",
      "sudo apt-get install tomcat7 -y"
    ]
  }
}

"terraform validate" gives me the error:

Error: Missing required argument

on main.tf line 52, in resource "aws_instance" "appserver1": 52: connection {

The argument "host" is required, but no definition was found.

Why remove your question? I think it was good and could help others with similar issue. — Marcin

Marcin Marcin · Accepted Answer · 2021-03-08T03:42:55

You have to specify connection details in the provisioner block. For example:

resource "aws_instance" "appserver1" {

  ami             = var.imageid
  instance_type   = var.instancetype
  key_name        = var.key
  security_groups = [aws_security_group.allow_all.name]


  provisioner "remote-exec" {

    connection {
       type        = "ssh"
       user        = "ubuntu"
       private_key = file(var.privatekeypath)
       host        = self.public_ip
    }

    inline = [
      "sudo apt-get update",
      "sudo apt-get install tomcat7 -y"
    ]
  }
}

But in your case, using user_data would be more suited.

Running aws instance with connection using terraform

2 Answers