NASM Simple Bootloader won't Load a Sector Using INT 13H

Question

Anything I have made so far works fine if I run it straight from the boot sector but I just can't get anything to work in terms of loading from the sector directly after. I have tried many different drive numbers: 0x00 --> 0x03, 0x80 --> 0x83. Also, this is basically exactly the same as ep.4 of Queso Fuego's OSDEV series

org 0x7c00
bits 16

mov bx, 0x1000
mov es, bx
mov bx, 0x0000

mov dh, 0x00
mov dl, 0x00
mov ch, 0x00
mov cl, 0x02

read_disk:
    mov ah, 0x02
    mov al, 0x01
    int 0x13
    
    jc read_disk

mov ax, 0x1000
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax

jmp 0x1000

times 510-($-$$) db 0

dw 0xaa55

mov ah, 0x00
mov al, 0x01
int 0x10

mov ah, 0x0b
mov bh, 0x00
mov bl, 0x01
int 0x10

mov si, testString
call print_string

hlt

print_string:
    mov ah, 0x0e
    mov bh, 0x00
    mov bl, 0x07

print_char:
    mov al, [si]
    cmp al, 0
    je end_print
    int 0x10
    add si, 1
    jmp print_char

end_print:
    ret

testString: db 'Kernel Booted!', 0xa, 0xd, 0

times 1024-($-$$) db 0

Any suggestions would be greatly appreciated, I've been stuck on this for days. I've been using INT 10H and INT 13H Wikipedia pages, thought they might be useful to see what I'm trying to do with the registers. Thank you in advance!

Note that if you fix the jump to be jmp 0x1000:0 as suggested in the answer, you also should add the following lines: 1. After org 0x7C00 the line section BOOTSECTOR start=7C00h and 2. after dw 0xAA55 the line section KERNEL follows=BOOTSECTOR vstart=0 -- this will insure that the mov si, testString uses the correct offset. — ecm

Brendan Brendan · Accepted Answer · 2020-09-07T20:39:57

The main problem is probably the "jmp 0x1000", which (depending on what CS is) possibly jumps to 0x0000:0x1000 (physical address 0x00001000) but could jump to 0x007C0:0x10000 (physical address 0x00008C00) or somewhere else. You loaded the sector at "0x1000:0x0000" (or physical address 0x00010000), so it's almost impossible for the jump to be right. Instead, you need a "far jump" like "jmp 0x1000:0x0000" that sets CS and IP (and doesn't just set IP and leave CS as whatever the BIOS felt like).

Other problems are:

a) the correct device number to use (in dl when you ask BIOS to load a sector) is whatever the BIOS told you the correct device number is (in dl when your code was started)

b) The BIOS could have left the stack (SS:SP) almost anywhere, which includes leaving the stack at the same address you overwrite when loading a sector. This means that there's a chance that loading a sector will trash the stack (while the BIOS is using it) and cause the BIOS to crash. You need to set SS:SP to something that won't cause problems before you do anything with any other memory. Note that your code sets SS without setting SP (which is also a mistake) and does that too late.

c) If a BIOS function like "int 0x13, ah=0x02" fails the BIOS tells you an error code (in ah). It's extremely important to use that error code to inform the user of what went wrong so that they can fix the problem (e.g. so they can determine if it's a software problem or a hardware problem) and aren't stuck with a computer that won't boot and no clue why. This also helps developers (you) find and fix bugs. This means using the error code to find an error string and then printing the error string. Unfortunately it's impossible to get good error handling in 512 bytes (the strings take up too much space); but you can easily fit "better than nothing" error handling in 512 bytes (e.g. print a raw hex code at the end of a generic string, like maybe "ERROR: Failed to load sector, BIOS error code 0x02" followed by "Boot aborted").

d) Floppy disks were notoriously unreliable; so standard practice was to retry (at least) 3 times before you assume an error is valid, while asking BIOS to reset the disk system ("int 0x13, ah=0x00") between (some) retries.

e) The hlt instruction does not stop the CPU forever - it merely asks the CPU to wait until an IRQ occurs (and for BIOS, IRQs from timer alone typically happen 18.2 times per second). This means that instead of the CPU stopping at your hlt it will continue executing code after the hlt (likely causing your code to print random garbage and then do a "return to undefined address because the routine wasn't called normally" and likely crash). To fix that use a loop; like ".die:", "hlt" then "jmp .die".

f) Floppy disks have been obsolete for about 20 years. For hard drives you have to deal with some kind of partitioning system and your boot loader won't/can't begin in the first sector of the disk. Instead, your boot loader will begin in the first sector of a partition.

g) BIOS should also be considered obsolete (replaced by UEFI). Even though BIOS still exists on old computers now, it won't exist on old computers when you finish writing an OS. For this reason it's better to learn about UEFI (and not bother learning about BIOS).

Note: If you are using BIOS, then it's better to rely on Ralph Brown's Interrupt list for documentation of BIOS functions. You can find that at http://www.ctyme.com/rbrown.htm (but you'll typically want the table of interrupts at http://www.ctyme.com/intr/int.htm ).

NASM Simple Bootloader won't Load a Sector Using INT 13H

1 Answers