Unity3d standard surface particle stream shader error in unity 2019

Question

I've been trying to make the shader example from unity's website to compile in unity3d 2019.

Shader "Custom/test" {
Properties {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Albedo (RGB)", 2D) = "white" {}
    _Glossiness ("Smoothness", Range(0,1)) = 0.5
    _Metallic ("Metallic", Range(0,1)) = 0.0
}
SubShader {
    Tags {"Queue"="Transparent" "RenderType"="Transparent"}
    Blend SrcAlpha OneMinusSrcAlpha
    ZWrite off
    LOD 200

    CGPROGRAM
    // Physically based Standard lighting model, and enable shadows on all light types
    #pragma surface surf Standard alpha vertex:vert

    // Use shader model 3.0 target, to get nicer looking lighting
    #pragma target 3.0

    sampler2D _MainTex;

     struct appdata_particles {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
        float4 color : COLOR;
        float4 texcoords : TEXCOORD0;
        float texcoordBlend : TEXCOORD1;
        };


    struct Input {
        float2 uv_MainTex;
        float2 texcoord1;
        float blend;
        float4 color;
    };


    void vert(inout appdata_particles v, out Input o) {
        UNITY_INITIALIZE_OUTPUT(Input,o);
        o.uv_MainTex = v.texcoords.xy;
        o.texcoord1 = v.texcoords.zw;
        o.blend = v.texcoordBlend;
        o.color = v.color;
      }


    half _Glossiness;
    half _Metallic;
    fixed4 _Color;


    void surf (Input IN, inout SurfaceOutputStandard o) {
        fixed4 colA = tex2D(_MainTex, IN.uv_MainTex);
        fixed4 colB = tex2D(_MainTex, IN.texcoord1);
        fixed4 c = 2.0f * IN.color * lerp(colA, colB, IN.blend) * _Color;

        o.Albedo = c.rgb;
        // Metallic and smoothness come from slider variables
        o.Metallic = _Metallic;
        o.Smoothness = _Glossiness;
        o.Alpha = c.a;
    }
    ENDCG
}
FallBack "Diffuse"
}

But the compilation gives an error: Shader error in 'Custom/test': invalid subscript 'texcoord' at line 157 (on d3d11)

I suspect there is a difference between unity 2017 for which the example was made and unity 2019, but i can't figure out what the problem is.

Liviu Marinescu Liviu Marinescu · Accepted Answer · 2019-11-27T13:42:03

Managed to figure it out:

Shader "Custom/StandardTransparentQueue" {
Properties {
    _Color ("Color", Color) = (1,1,1,1)
    _MainTex ("Albedo (RGB)", 2D) = "white" {}
    _Glossiness ("Smoothness", Range(0,1)) = 0.5
    _Metallic ("Metallic", Range(0,1)) = 0.0
}
SubShader {
    Tags {"Queue"="Transparent" "RenderType"="Transparent"}
    Blend SrcAlpha OneMinusSrcAlpha
    ZWrite off
    LOD 200

    CGPROGRAM
    // Physically based Standard lighting model, and enable shadows on all light types
    #pragma surface surf Standard alpha vertex:vert

    // Use shader model 3.0 target, to get nicer looking lighting
    #pragma target 3.0

    sampler2D _MainTex;

     struct appdata_particles {
        float4 vertex : POSITION;
        float3 normal : NORMAL;
        float4 color : COLOR;
        float4 texcoords : TEXCOORD0;
        float texcoordBlend : TEXCOORD1;
        };


    struct Input {
        float2 texcoord;
        float2 texcoord1;
        float blend;
        float4 color;
    };


    void vert(inout appdata_particles v, out Input o) {
        UNITY_INITIALIZE_OUTPUT(Input,o);
        o.texcoord = v.texcoords.xy;
        o.texcoord1 = v.texcoords.zw;
        o.blend = v.texcoordBlend;
        o.color = v.color;
      }


    half _Glossiness;
    half _Metallic;
    fixed4 _Color;


    void surf (Input IN, inout SurfaceOutputStandard o) {
        fixed4 colA = tex2D(_MainTex, IN.texcoord);
        fixed4 colB = tex2D(_MainTex, IN.texcoord1);
        fixed4 c = 2.0f * IN.color * lerp(colA, colB, IN.blend) * _Color;

        o.Albedo = c.rgb;
        // Metallic and smoothness come from slider variables
        o.Metallic = _Metallic;
        o.Smoothness = _Glossiness;
        o.Alpha = c.a;
    }
    ENDCG
}
FallBack "Diffuse"
}

In unity 2019 it expects texcoord to be a member of the Input structure instead of uv_MainTex.

Hope it helps others :)

Unity3d standard surface particle stream shader error in unity 2019

1 Answers