Pipes (Haskell lib) - piping pipes with different state monad

Question

My goal is to have the last value produced equal to 80 (40 + 40) (see code below)...

import Pipes
import Pipes.Prelude
import Pipes.Lift
import Control.Monad.State.Strict

data Input = A Integer | B Integer | C Integer

main :: IO ()
main = runEffect $ each [A 10,B 2,C 3,A 40,A 40] >-> pipeline >-> print


pipeline :: Pipe Input Integer IO ()
pipeline = for cat $ \case
  A x -> yield x >-> accumulate
  B x -> yield x
  C x -> yield x

accumulate :: Pipe Integer Integer IO ()
accumulate = evalStateP 0 accumulate'


accumulate' :: Pipe Integer Integer (StateT Integer IO) ()
accumulate' = go
  where
    go = do
        x <- await
        lift $ modify (+x)
        r <- lift get
        yield r
        go

With this example Input As are not accumulated...yield x >-> accumulate on Input A does do what I'm expected, the stream is a new one each time...

Piping pipes with different state monad sequentially works well but here somehow I want to nest them in the case pattern (like a substream somehow)...

dfeuer dfeuer · Accepted Answer · 2019-11-14T15:25:16

The problem is that you call evalStateP too early, discarding state you want to preserve across calls to accumulate. Try something like this:

pipeline :: Pipe Input Integer IO ()
pipeline = evalStateP 0 $ for cat $ \case
  A x -> yield x >-> accumulate
  B x -> yield x
  C x -> yield x

accumulate :: Pipe Integer Integer (StateT Integer IO) ()
accumulate = for cat $ \x -> do
        modify (+x)
        r <- get
        yield r

Note that Proxy has a MonadState instance, so you don't need to lift state operations manually if you use mtl.

Pipes (Haskell lib) - piping pipes with different state monad

1 Answers