Is it possible to create option types in ABAP?

Question

A continued annoyance in ABAP is that one is unable to distinguish a variable that was never set from one that was set to the initial value for its data type, and that failing accesses to internal tables via itab[...] expressions throw CX_SY_ITAB_LINE_NOT_FOUND which is costly in terms of runtime to deal with.

For enumerated types, one can define the first variant as invalid to guard against the first confusion:

TYPES:
  BEGIN OF ENUM my_bool,
    invalid,
    true,
    false,
  END OF ENUM my_bool.

(Do not actually use this type as an ABAP_BOOL replacement. The way predicative method calls behave, a method meth returning a my_bool would lead to obj->meth( ) inside an IF obj->meth( ). being truthy only if it returns invalid, since the predicative method call is equivalent to IF obj->meth( ) IS NOT INITIAL.)

For non-enumerated types, we're out of luck. Trying to implement something like an option type to return from methods that tried and failed to access some data is blocked by the weak typing of generics:

CLASS zcl_option DEFINITION
    FINAL.
PUBLIC SECTION.
  CLASS-METHODS some
    IMPORTING VALUE(val) TYPE any
    RETURNING VALUE(option) TYPE REF TO zcl_option.
  CLASS-METHODS none
    RETURNING VALUE(option) TYPE REF TO zcl_option.
  METHODS is_some
    RETURNING VALUE(is_some) TYPE abap_bool.
  METHODS get
    RETURNING VALUE(val) TYPE ???.
ENDCLASS.

where trying to use a generic type in the return value of get fails with "returning parameters must be fully typed".

Is there a way I can construct something like the option type in ABAP, or even more generally sum types?

I think there's no better answer than your proposal, and you might obtain only opinionated answers how to code it generically (for instance by using inheritance and defining the value in the subclass as a READ-ONLY attribute, etc.) Maybe you should give the context in which you want to use it, as it currently looks very theoretical, so that to get more precise answers. — Sandra Rossi
@SandraRossi While I have a concrete context in mind, I'd find such a type generally useful to return from methods that query resources that may or may not exist, i.e. where non-existence is not an exceptional state as such. (Example: get the TADIR entry of a class, if it exists. For example, many classes generated by things like the BSP framework don't have one, but that's not an error.) — ACuriousMind

Pilot Pilot · Accepted Answer · 2019-07-15T14:44:34

This is what I came up with. I was about to throw it away when it started looking not 100 % useless, so here it goes :D :D

PROGRAM ztest_options_tongue_in_cheek.

*&---------------------------------------------------------------------*
TYPES:
  BEGIN OF ENUM t_options,
    some,
    none,
  END OF ENUM t_options.

DEFINE macro_option_type.
  CLASS zcl_option_&1 DEFINITION FINAL.
    PUBLIC SECTION.
      METHODS:
        constructor
          IMPORTING VALUE(i_val)     TYPE &1
                    VALUE(i_option)  TYPE t_options,
        is_some
          RETURNING VALUE(e_is_some) TYPE abap_bool,
        get
          RETURNING VALUE(e_val)     TYPE &1.
    PRIVATE SECTION.
      DATA:
        lv_the_value TYPE &1,
        lv_is_none   TYPE abap_bool.
  ENDCLASS.

  CLASS zcl_option_&1 IMPLEMENTATION.
    METHOD constructor.
      lv_the_value = i_val.
      lv_is_none   = COND #( WHEN i_option = none THEN abap_true ELSE abap_false ).
    ENDMETHOD.

    METHOD is_some.
      e_is_some = COND #( WHEN lv_is_none = abap_false THEN abap_true ELSE abap_false ).
    ENDMETHOD.

    METHOD get.
      e_val = lv_the_value.
    ENDMETHOD.
  ENDCLASS.
END-OF-DEFINITION.
*&---------------------------------------------------------------------*


*&---------------------------------------------------------------------*
* Static declaration of required option types
macro_option_type:
  i, string, char256, float, uzeit, datum.
*&---------------------------------------------------------------------*


*&---------------------------------------------------------------------*
DEFINE option.
* Rely on garbage collector for simplicity
  &2 = NEW zcl_option_&1( i_val = CONV &1( &3 ) i_option = &4 ).
END-OF-DEFINITION.
*&---------------------------------------------------------------------*


*&---------------------------------------------------------------------*
DEFINE declare_init_option.
  DATA &2 TYPE REF TO zcl_option_&1.
  option &1 &2 space none.
END-OF-DEFINITION.
*&---------------------------------------------------------------------*



*&---------------------------------------------------------------------*
START-OF-SELECTION.
*&---------------------------------------------------------------------*
  PERFORM test_options.


*&---------------------------------------------------------------------*
*& Form TEST_OPTIONS
*&---------------------------------------------------------------------*
FORM test_options .

  declare_init_option:
    i      lo_integer_option,
    string lo_string_option,
    float  lo_float_option,
    uzeit  lo_time_option.



  option i lo_integer_option 123 some.

  option string lo_string_option 'I am now a string' some.

  option string lo_string_option `` none. "back to none

* e.g.,
  IF lo_integer_option->is_some( ) = abap_true.
    WRITE: / |lo_integer_option is { lo_integer_option->get( ) }|.
  ELSE.
    WRITE: / 'lo_integer_option is nothing'.
  ENDIF.

ENDFORM.

Is it possible to create option types in ABAP?

3 Answers