Functional Dependencies / Type Families

Question

With functional dependencies I can constrain type of dependent parameter in a type class using multi-parameter type classes. Just like this:

{-# LANGUAGE FunctionalDependencies, MultiParamTypeClasses,TypeSynonymInstances  #-}

class (Num a, Integral b) => F a b | a -> b where
  f :: a -> b

instance F Int Int where
  f = id

instance F Float Integer where
  f = truncate

And everything'll work perfectly.

> f (1 :: Int)
1
> f (1.9 :: Float)
1

But if I try to write something like

instance F Double String where
  f = show

I'll get the following compilation error:

No instance for (Integral String)
arising from the superclasses of an instance declaration
Possible fix: add an instance declaration for (Integral String)
In the instance declaration for `F Double String'

Is there a way to approach this with type families instead of fundeps?

fuz fuz · Accepted Answer · 2011-04-11T18:38:35

I guess you want to have something like this:

{-# LANGUAGE TypeFamilies, FlexibleContexts  #-}
class Num a => G a where
  type B a
  g :: (Integral (B a)) => a -> B a

instance G Int where
  type B Int = Int
  g = id

instance G Float where
  type B Float = Integer
  g = truncate

This example is not directly using a type family, but an associated type synonym, which is activated by the same flag. The idea is fairly easy. Instead of explicit giving a second parameter to the typeclass, we define a type synonym, that is filled in with the appropriate type.

This is also my first time to use associated type synonyms, but it seems to be a quite cool feature.

Functional Dependencies / Type Families

2 Answers