XSLT 1.0 (xsltproc) - How to replace last occurence of a character?

Question

I'm trying to replace the last occurrence of '.' character with '/' character in using XSLT (xslt 1.0 xsltproc). How can I do that?

Input.xml

<testng-results>
<suite>
<test>
<class name="system.apps.webdriver.tests.crm.mot.CreateTerritoryProposalTest">
<test-method status="PASS" started-at="2019-02-07T18:24:47Z" name="initTest">
</test-method>
<test-method status="FAIL" started-at="2019-02-07T18:24:47Z" name="ActListsForContactShowsContactRelatedTasksTest">
</test-method>
</class>
</test>
</suite>
</testng-results>

Current XSL:

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">

    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="/">
        <Suite>
            <xsl:for-each select="testng-results/suite/test/class/test-method">
                        <Test>
                            <Result_Path> <xsl:value-of select="concat('testngreports/', ../@name, '/', @name)"/> </Result_Path>
                        </Test>
            </xsl:for-each>
        </Suite>
    </xsl:template>
</xsl:stylesheet>

Expected Result XML:

<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <Test>
    <Result_Path>testngreports/system.apps.webdriver.tests.crm.mot/CreateTerritoryProposalTest/initTest</Result_Path>
  </Test>
  <Test>
    <Result_Path>testngreports/system.apps.webdriver.tests.crm.mot/CreateTerritoryProposalTest/ActListsForContactShowsContactRelatedTasksTest</Result_Path>
  </Test>
</Suite>

Current Output XML:


<?xml version="1.0" encoding="UTF-8"?>
<Suite>
  <Test>
    <Result_Path>testngreports/system.apps.webdriver.tests.crm.mot.CreateTerritoryProposalTest/initTest</Result_Path>
  </Test>
  <Test>
    <Result_Path>testngreports/system.apps.webdriver.tests.crm.mot.CreateTerritoryProposalTest/ActListsForContactShowsContactRelatedTasksTest</Result_Path>
  </Test>
</Suite>

Summary:

Current Output:

testngreports/system.apps.webdriver.tests.crm.mot.CreateTerritoryProposalTest/initTest

Expected Output:

testngreports/system.apps.webdriver.tests.crm.mot/CreateTerritoryProposalTest/initTest

Last '.' character should be replaced with '/'

michael.hor257k michael.hor257k · Accepted Answer · 2019-04-16T23:14:15

With xsltproc - i.e. the libxslt processor - you can take advantage of the EXSLT str:tokenize() extension function and do:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:str="http://exslt.org/strings"
extension-element-prefixes="str">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/testng-results">
    <Suite>
        <xsl:for-each select="suite/test/class">
            <xsl:variable name="class-name">
                <xsl:for-each select="str:tokenize(@name, '.')">
                    <xsl:value-of select="."/> 
                    <xsl:choose>
                        <xsl:when test="position() >= last() - 1 ">/</xsl:when>
                        <xsl:otherwise>.</xsl:otherwise>
                    </xsl:choose>
                </xsl:for-each>
            </xsl:variable>
            <xsl:for-each select="test-method">
                <Test>
                    <Result_Path>
                        <xsl:text>testngreports/</xsl:text>
                        <xsl:value-of select="$class-name"/> 
                        <xsl:value-of select="@name"/> 
                    </Result_Path>
                </Test>
            </xsl:for-each>
        </xsl:for-each>
    </Suite>
</xsl:template>

</xsl:stylesheet>

XSLT 1.0 (xsltproc) - How to replace last occurence of a character?

2 Answers