gnuplot partially stacked bars

Question

I would like to make a gnuplot graph with one full bar and another one stacked. The data is something like

x   data    E   M   L
[10,20) 0.000000    1.081916    2.0958133   5.473606
[20,40) 0.000000    2.331769    2.1402838   4.528341
[40,80) 3.262375    2.201788    1.3499280   3.023847
>80 2.368121    2.132216    0.7322889   2.610368

where E, M and L are the three "green" components.

I have tried to do something like

set style data histograms
set style histogram rowstacked
#set style histogram cluster gap 1
set style fill solid
...

plot newhistogram, "size_class_data/tree_paracou.txt" using 2:xticlabel(1) linecolor rgb data_color title "Model",\
newhistogram, '' using 3:xticlabel(1) linecolor rgb early_color title "d",\
'' using 4 linecolor rgb mid_color title "g",\
'' using 5 linecolor rgb late_color title "f"

but the two graphs lie on two different parts of the x axis.

Christoph Christoph · Accepted Answer · 2019-01-25T17:37:12

The newhistogram command has an option at for setting the coordinate of the first box.

In you case you can fix the boxwidth, and start the second histogram at 0 + boxwidth:

set style data histograms
set style histogram rowstacked
set style fill solid
set boxwidth 0.33 absolute

plot "foo.dat" using 2:xticlabel(1) skip 1 linecolor rgb "black"  title "Model",\
newhistogram at 0.33, '' using 3 skip 1 linecolor rgb "red" title "d",\
'' using 4 skip 1 linecolor rgb "green" title "g",\
'' using 5 skip 1 linecolor rgb "blue" title "f"

gnuplot partially stacked bars

1 Answers