firemonkey convert mp3 stream to hex and reverse

Question

i try to save a audio from mobile microphone to a Tmemorystream and then convert it to hex with this function:

function StreamToHexStr(AStream: TStream): string;
const
 HexArr: array[0..15] of char =
 ('0','1','2','3','4','5','6','7','8','9','A','B','C','D','E','F');
var
 AByte: Byte;
 i: Integer;
begin
 SetLength(Result, AStream.Size * 2);
 AStream.Position := 0;
 for i := 0 to AStream.Size - 1 do
 begin
   AStream.ReadBuffer(AByte, SizeOf(AByte));
   Result[i * 2 + 1] := HexArr[AByte shr 4];
   Result[i * 2 + 2] := HexArr[AByte and $0F];
 end;
end;

the output is a hexadecimal string

after transfer it a a second device i have to change the hex code to a Tmemorystream and the play it with this function:

Stream := TMemoryStream.Create;
try
  Writer := TBinaryWriter.Create(Stream);
  try
    Writer.Write(TEncoding.UTF8.GetBytes(ReciavedSTR));
  finally
    Writer.Free;
  end;
  Stream.SaveToFile( TPath.GetSharedMoviesPath()+'/record2.mp3' );

but the record2.mp3 is not playable and it just include the converted hex string

what is wrong with my code?

for a simple test when i save the recorded stream to a file with this code

FOutputStream.SaveToFile( TPath.GetSharedMoviesPath()+'/record.mp3' );

it working good.

update project concept:

the hardware transmitter get 406 hex char from mobile phone on serial port and transfer it to second device,then the receiver deliver the hex string to second mobile phone , the second phone must join the strings and convert them to a hear-able sound.

a sample output of base64 to stream and stream save to file

sample mp3 file

Your forward and reverse functions bear no resemblance to each other, so of course it will not work. What makes you imagine that UTF8 is related to the hexadecimal representation of a binary stream? — Dsm
Most likely, you don't convert the hex string back to binary. Not sure why you convert the binary to a hex string in the first place. — Ken Bourassa
@Dsm is thre a way to convert the stream ?! i used TEncoding.UTF8.GetBytes the convert string to byte — peiman F.
Why would you want to encode a binary file as a hex string? Why choose base16? If you have to transmit as text then isn't base 64 more efficient. But still, isn't binary even more efficient. — David Heffernan
@peimanF. NO MATTER HOW you decide to encode the data at the transmitter layer, the receiver layer must decode using the SAME format. In your original code, you encode to a hex-formatted string, but decode that string as if it were UTF-8 bytes instead. That is a clear mismatch in formats. You need to decode the received string as a hex string in order to get back the original bytes (ie, for every 2-char pair in the string, convert each char to the corresponding 4 bits, and then merge the 2 sets of bits together into a single byte). — Remy Lebeau

G Wimpassinger G Wimpassinger · Accepted Answer · 2018-12-06T20:43:57

At first, let me answer your initial question

How to convert a stream to and from base16 (aka ASCII-HEX).

Your code to convert to base16 is correct, here is an essentially equal version:

function StreamToHexStr(const AStream: TStream): String;
const
  cMap : array[0..15] of Char = (
    '0', '1', '2', '3', '4', '5', '6', '7', '8', '9', 
    'A', 'B', 'C', 'D', 'E', 'F');
var
  lData: Byte;
  lPos: Integer;
begin
  Setlength(Result, AStream.Size * 2);
  AStream.Position := 0; 
  lPos := Low(Result);
  while AStream.ReadData(lData) = sizeof(lData) do begin
    Result[lPos]     := cMap[lData shr 4];
    Result[lPos + 1] := cMap[lData and $0F];
    Inc(lPos, 2);
  end;
end;

To convert the string back into a stream, try this:

procedure HexStrToStream(const AString: String; AStream: TStream);
const
  // Mapping vom ASCII-Code to value
  cMap: array['0'..'F'] of Byte  = (
    0, 1, 2, 3, 4, 5, 6, 7, 8, 9,  // $30..$39 / '0'..'9'
    100, 100, 100, 100, 100, 100, 100, //  $3A..$40
    10, 11, 12, 13, 14, 15); // $41..$46 / 'A'..'F'
var
  lPos: Integer;
begin
  lPos := Low(AString);
  while lPos < High(AString) do begin
    AStream.WriteData(UInt8(cMap[AString[lPos]] shl 4 + cMap[AString[lPos + 1]]));
    Inc(lPos, 2);
  end;
end;

To use this code simply do:

Base16String := StreamToHexStr(MP3Stream);

on the sender and on the receiver do:

lRecvStream := TMemoryStream.Create();
try
  HexStrToStream(Base16RecvString, RecvStream);
  lRecvStream.SaveToFile('Record.mp3');
finally
  lRecvStream.Free();
end;

How to do the same for base64

With a TMemoryStream on the sending side you simply do:

lString := TNetEncoding.Base64.EncodeBytesToString(lInStream.Memory, lInStream.Size);

and on the receiving side you use a TBytesStream (which is a descendant of a TMemoryStream):

lRecvStream := TBytesStream.Create(TNetEncoding.Base64.DecodeStringToBytes(lString));
try
  lRecvStream.SaveToFile('Record.mp3');
finally
  lRecvStream.Free();
end;

Things you may consider

During the transfer of the data, some bytes may be changed or get lost. Sometimes whole packets will not be received. Depending on your requirements, your application may need some protection against such errors.

firemonkey convert mp3 stream to hex and reverse

1 Answers

How to convert a stream to and from base16 (aka ASCII-HEX).

How to do the same for base64

Things you may consider