Removing internal link to Word-templates via VBA

Question

I'm trying to create a small VB-application that removes the internal link in Word Documents, to their templates.

I have found this guide http://word.tips.net/Pages/T001437_Batch_Template_Changes.html and am trying to modify it, to use with VBA instead of Macro programming inside of Office.

However, I'm getting stuck on how to get the Document.Open to work. Any help is appreciated.

This is supposed to run as a free-standing application, and not runt from within Word. I'm looking for a way to perform what the Macro does, but not from within Word.

Sorry, I'm a little confused with the references to VBA/Macros and the tags visual-studio-2010 and vba. VBA is the macro language used from within Office. Are you trying to do this from Interop in VS or VSTO (that wouldn't be a VBA application, that would be a VS application)? What part of Document.Open trips you up? Are you adopting the referenced code on just trying to put it in the Document.Open event sink? — Todd Main
I've changed your tags to match your question, but please change them and clarify your question if I got it wrong. Please give more details on what's going on with Document.Open. — Lance Roberts
Hej ... are you looking for help on the 1st or 2nd macro from the page you mentioned? — MikeD

Simon G. Simon G. · Accepted Answer · 2011-04-04T20:44:58

There are two pieces of bad news to give here.

1) A document has to have a template. You cannot remove it, only change it to something else.

2) Changing a template does nothing anyway. See this page.

I am wonder if the problem with the Open method is that you are trying to open ".doc" extension files, not the modern ".docx" extension files. The VBA subroutine you linked to only does ".doc" files. This VBA code does both:

Function StringEndsWith( _
    ByVal strValue As String, _
    CheckFor As String) As Boolean

  Dim sCompare As String
  Dim lLen As Long

  lLen = Len(CheckFor)
  If lLen > Len(strValue) Then Exit Function
  sCompare = Right(strValue, lLen)
  StringEndsWith = StrComp(sCompare, CheckFor, vbTextCompare) = 0
End Function


Sub ChangeTemplates()
    Dim strDocPath As String
    Dim strTemplateB As String
    Dim strCurDoc As String
    Dim docCurDoc As Document

    ' set document folder path and template strings
    strDocPath = "C:\tmp\"

    ' get first doc - only time need to provide file spec
    strCurDoc = Dir(strDocPath & "*.doc*")

    ' ready to loop (for as long as file found)
    Do While strCurDoc <> ""
        If (StringEndsWith(strCurDoc, ".doc") Or StringEndsWith(strCurDoc, ".docx")) Then
            ' open file
            Set docCurDoc = Documents.Open(FileName:=strDocPath & strCurDoc)
            ' change the template back to Normal
            docCurDoc.AttachedTemplate = ""
            ' save and close
            docCurDoc.Close wdSaveChanges
        End If
        ' get next file name
        strCurDoc = Dir
    Loop
    MsgBox "Finished"
End Sub

Removing internal link to Word-templates via VBA

2 Answers