How do you load bash_profile for bash commands run from perl script?

Question

I wrote simple command that lets me run the last N commands from terminal history. It looks like this: $> r 3 which will replay the last 3 commands.

I have the following alias in my bash profile: alias r="history -w; runlast $1"

And then the following simple perl script for the runlast command:

#!/usr/bin/env perl
use strict;
use warnings;

my $lines = $ARGV[0] || exit;

my @last_commands = split /\n/, 
    `bash -ic 'set -o history; history' | tail -$lines`;

@last_commands = 
    grep { $_ !~ /(^r |^history |^rm )/ } 
    map { local $_ = $_; s/^\s+\d+\s+//; $_ } 
    @last_commands;

foreach my $cmd (@last_commands) {
  system("$cmd");
}

This works but my bash profile has aliases and other features (e.g. color output) I want the perl script to have access to. How do I load the bash profile for perl so it runs the bash commands with my bash profile? I read somewhere that if you "source the bash profile" for perl you can get it to work. So I tried adding source ~/.bash_profile; to my r command alias but that didn't have an effect. I'm not sure if I was doing that correctly, though.

See also How to call a function (defined in shell script) in a Perl script and Running system command under interactive bash shell — Håkon Hægland
Its generally a bad idea to use aliases in a script because that means the behaviour can vary depending on where it is run, which is a support nightmare. It is better to use functions instead. — cdarke
$1 in the alias definition doesn't mean what you hope it means. Anyway, the only thing you really need to know about aliases is, use functions instead. — tripleee

zdim zdim · Accepted Answer · 2018-08-19T07:14:14

The system forks a process in which it runs a shell, which is non-login and non-interactive; so no initialization is done and you get no aliases. Also note that the shell used is /bin/sh, which is generally a link to another shell. This is often bash but not always, so run bash explicitly.

To circumvent this you need to source the file with aliases, but as bash man page says

Aliases are not expanded when the shell is not interactive, unless the expand_aliases shell option is set using shopt (see the description of shopt under SHELL BUILTIN COMMANDS below).

Thus you need shopt -s expand_aliases, as mentioned. But there is another screw: on that same physical line aliases are not yet available; so it won't work like this in a one-liner.

I'd also recommend to put aliases in .bashrc, or in a separate file that is sourced.

Solutions

Add shopt -s expand_aliases to your ~/.bashrc, and before the aliases are defined (or the file with them sourced), and run bash as a login shell
```
system('/bin/bash', '-cl', 'source ~/.bashrc; command');
```
where -l is short for --login.

In my tests the source ~/.bashrc wasn't needed; however, the man page says

When bash is invoked as an interactive login shell, or as a non-interactive shell with the --login option, it first reads and executes commands from the file /etc/profile, if that file exists. After reading that file, it looks for ~/.bash_profile, ~/.bash_login, and ~/.profile, in that order, and reads and executes commands from the first one that exists and is readable.

and goes on to specify that ~/.bashrc is read when an interactive shel that is not login runs. So I added explicit sourcing.

In my tests sourcing .bashrc (with shopt added) while not running as a login shell didn't work, and I am not sure why.

This is a little heavy-handed. Also, initialization may be undesirable to run from a script.
Source ~/.bashrc and issue shopt command, and then a newline before the command
```
system('/bin/bash', '-c', 
    'source ~/.bashrc; shopt -s expand_aliases\ncommand');
```
Really. It works.

Finally, is this necessary? It asks for trouble, and there is probably a better design.

Other comments

The backticks (qx) is context-aware. If it's used in list context – its return assigned to an array, for example – then the command's output is returned as a list of lines. When you use it as the argument for split then it is in the scalar context though, when all output is returned in one string. Just drop split
```
my @last_commands = `bash -ic 'set -o history; history $lines`;
```
where I also use history N to get last N lines. In this case the newlines stay.
history N returns last N lines of history so there is no need to pipe to last
Regex substitution in a map can be done without changing the original
```
map { s/^\s+\d+\s+//r } @last_commands;
```
With /r modifier the s/// operator returns the new string, not changing the original. This "non-destructive substitution" has been available since v5.14
No need to explicitly use $_ in the last grep, and no need for parenthesis in regex
```
grep { not /^r |^history |^rm ?/ } ...
```
or
```
grep { not /^(?:r|history|rm)[ ]?/ } ...
```
where parens are now needed, but as it is only for grouping the ?: makes it not capture the match. I use [ ] to emphasize that that space is intended; this is not necessary.

I also added ? to make space optional since history (and r?) may have no space.

How do you load bash_profile for bash commands run from perl script?

3 Answers