Arduino can't output in both led screen and serial monitor at the same time

Question

I am trying to have Arduino output on both LED screen using the LiquidCrystal library, and on Serial Monitor (later to a txt file or something like that).

In my code, I commented out Serial.begin(9600) and then the screen outputs correctly, but as soon as I include it, the serial monitor outputs fine but the screen flips out and outputs gibberish. I'm fairly new and I know there's something basic I don't know like 9600 should be augmented because so much power is needed maybe?

#include <LiquidCrystal.h>
#include <DHT.h>
#include <math.h>

/*
    * Cannot do both screens and log in the console.
    * Currently Serial 9600 is commented out, to allow to print on the screen
    * Need Fixing
*/

#include "DHT.h"

#define DHTPIN 8     // what digital pin we're connected to


#define DHTTYPE DHT11   // DHT 11
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

DHT dht(DHTPIN, DHTTYPE);

LiquidCrystal lcd(1, 2, 4, 5, 6, 7);

void setup() {
    //Serial.begin(9600);
    Serial.println("Temperature Recorder");

    dht.begin();

    // Now LiquidCrystal led monitor stuff
    lcd.begin(16,2);
    lcd.setCursor(2,0);
    lcd.print("** Wanet **");
    delay(1500);
    lcd.setCursor(1,1);
    lcd.print("Motherfuckers.");
    delay(3000);
    lcd.clear();
}

void loop() {
    // Wait a few seconds between measurements.
    delay(1000);

    // Reading temperature or humidity takes about 250 milliseconds!
    // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
    float h = dht.readHumidity();
    // Read temperature as Celsius (the default)
    float t = dht.readTemperature();
    // Read temperature as Fahrenheit (isFahrenheit = true)
    float f = dht.readTemperature(true);

    // Check if any reads failed and exit early (to try again).
    if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println("Failed to read from DHT sensor!");
    return;
    }

    // Compute heat index in Fahrenheit (the default)
    float hif = dht.computeHeatIndex(f, h);
    // Compute heat index in Celsius (isFahreheit = false)
    float hic = dht.computeHeatIndex(t, h, false);

    Serial.print("Humidity: ");
    Serial.print(h);
    Serial.print(" %\t");
    Serial.print("Temperature: ");
    Serial.print(t);
    Serial.print(" *C ");
    Serial.print(f);
    Serial.print(" *F\t");
    Serial.print(" | Heat index: ");
    Serial.print(hic);
    Serial.print(" *C ");
    Serial.print(hif);
    Serial.println(" *F");
    Serial.println("------------------------------------");

    //   led screen printing
    lcd.setCursor(0,0);
    lcd.print("Temp:  Humidity:");
    lcd.setCursor(0,1);
    lcd.print(t);
    lcd.print("   ");
    lcd.print(round(f));
    lcd.print("%");

    delay(5000);
    lcd.clear();
    lcd.setCursor(2,0);
    lcd.print("The world");
    lcd.setCursor(4,1);
    lcd.print("OURS");
    delay(6000);
}

Cheers

Tommaso Fontana Tommaso Fontana · Accepted Answer · 2018-07-14T06:48:18

On the docs of Arduino's Serial

Serial

It communicates on digital pins 0 (RX) and 1 (TX) as well as with the computer via USB. Thus, if you use these functions, you cannot also use pins 0 and 1 for digital input or output.

You have two options or you don't use those 2 pins

like this LiquidCrystal lcd(2, 3, 4, 5, 6, 7);

or if you must have those pin you might consider to use a library like softwareSerial which emulates the serial communication a pair of pin of your choice. but the serial monitor via USB won't work anyway.

Arduino can't output in both led screen and serial monitor at the same time

2 Answers

Serial