Forcing same palette on multiple pm3d plots in gnuplot

2
votes

Following the great info on splot pm3d I want to create two color / contour plots with same color range.

Below code creates two plots. The way the data comes in the first data set has z-data 2.0 to 5.5. The second 1.5 to 5.5. I would like both plots to use and show the same color key scale for both for better comparison. (i.e. 2 to 6)

I tried using zrange but it did not work.

#- BASE ---------------------------------------------

reset
#set zrange [2:6]
set contour
unset surface
set cntrparam levels incr 2.0,0.5,8.0

set view map
set xrange [0:2184]
set yrange [0:1472]

set dgrid3d 100,100,4

set table "ap130_base_contour.txt"
splot 'ap130_base.dat' using 11:12:14
unset table

unset contour
set surface
set table "ap130_base_dgrid.txt"
splot 'ap130_base.dat' using 11:12:14
unset table

reset
set pm3d map
unset key
set palette defined (0 '#352a87', 1 '#0363e1',2 '#1485d4', 3 '#06a7c6', 4 '#38b99e', 5 '#92bf73', 6 '#d9ba56', 7 '#fcce2e', 8 '#f9fb0e')
set autoscale fix
set grid

set terminal png size 2184,1472 enhanced font "Helvetica,20"
set output 'ap130_base.png'

splot 'ap130_base_dgrid.txt' w pm3d, 'ap130_base_contour.txt' w l lc rgb "black"

set output
set  terminal X11




#- TSFF ---------------------------------------------

reset
#set zrange [2:6]
set contour
unset surface
set cntrparam levels incr 2.0,0.5,8.0

set view map
set xrange [0:2184]
set yrange [0:1472]

set dgrid3d 100,100,4

set table "ap130_tsff_contour.txt"
splot 'ap130_tsff.dat' using 11:12:14
unset table

unset contour
set surface
set table "ap130_tsff_dgrid.txt"
splot 'ap130_tsff.dat' using 11:12:14
unset table

reset
set pm3d map
unset key
set palette defined (0 '#352a87', 1 '#0363e1',2 '#1485d4', 3 '#06a7c6', 4 '#38b99e', 5 '#92bf73', 6 '#d9ba56', 7 '#fcce2e', 8 '#f9fb0e')
set autoscale fix
set grid

set terminal png size 2184,1472 enhanced font "Helvetica,20"
set output 'ap130_tsff.png'

splot 'ap130_tsff_dgrid.txt' w pm3d, 'ap130_tsff_contour.txt' w l lc rgb "black"

set output
set  terminal X11

Note the color scale i the first plot from 2.0 to 5.5

enter image description here

In the second plot from 1.5 to 5.5

enter image description here

I would like both plots to have a color scale from i.e. 1 to 6.

Your input is appreciated. Gert

1
gnuplot
set cbrange [1:6] - Christoph
I want to add that the proposed setting works. To expand on this, adding a label to the color scale works as well (set cblabel "Text"). Nice to see how systematic gnuplot commands are. - Gert Gottschalk

1 Answers

1
votes

Try

set zrange[2:6]
set cbrange[2:6]

It should do the trick.