Save one model in multiple associations for parent object at once

Question

I have two models - Organization and User Organization has many users and also belongs to one owner(owner is User model too).

I have sign up form for Organization, where user can enter name for organization and name and password for user(user is a nested object for organization in form). After successful sign up I need to have an Organization with associated owner(User model) and also, this user should belong to this organization. So basically, created user should be owner and should be in list of has_many :users association after sign up.

I have success in creating organization with user as owner association, but I want user to be in has_many :users association after creation too. In Rails, I would just add after_create callback and set organization_id for user in this case, but since ecto doesn't have callbacks, how should I do this? I have read about Ecto.Multi, but I am not sure if it is right approach(it looks like overkill for me) and not sure how it can be used for this case.

Just in case, here is my code for models and for sign up form.

defmodule HappyClient.Organization do
  use HappyClient.Web, :model

  schema "organizations" do
    field :name, :string
    belongs_to :owner, HappyClient.User, foreign_key: :owner_id
    has_many :users, HappyClient.User

    timestamps()
  end

  def changeset(struct, params \\ %{}) do
    struct
    |> cast(params, [:name])
    |> validate_required([:name])
  end

  def registration_changeset(struct, params) do
    struct
    |> changeset(params)
    |> cast_assoc(:owner, required: true, with: &HappyClient.User.registration_changeset/2)
  end
end

User model

defmodule HappyClient.User do
  use HappyClient.Web, :model

  schema "users" do
    field :email, :string
    field :name, :string
    field :password_hash, :string
    field :is_admin, :boolean, default: false
    field :is_operator, :boolean, default: false
    belongs_to :organization, HappyClient.Organization

    field :password, :string, virtual: true

    timestamps()
  end

  @required_fields ~w(email name)a
  @optional_fields ~w(is_admin is_operator)a

  def changeset(struct, params \\ %{}) do
    struct
    |> cast(params, @required_fields)
    |> validate_required([:email, :name])
    |> validate_format(:email, ~r/@/)
    |> assoc_constraint(:organization)
  end

  def registration_changeset(struct, params) do
    struct
    |> changeset(Map.merge(params, %{"is_admin" => true}))
    |> cast(params, [:password], [])
    |> validate_required([:password])
    |> validate_length(:password, min: 6, max: 100)
    |> hash_password
  end

  defp hash_password(changeset) do
    case changeset do
      %Ecto.Changeset{valid?: true,
                      changes: %{password: password}} ->
        put_change(changeset,
                   :password_hash,
                   Comeonin.Bcrypt.hashpwsalt(password))
      _ ->
        changeset
    end
  end
end

Sign up form

<h1>Registration</h1>

<%= form_for @changeset, organization_path(@conn, :create), fn f -> %>
  <%= if @changeset.action do %>
    <div class="alert alert-danger">
      <p>There are some errors</p>
    </div>
  <% end %>
  <div class="form-group">
    <%= text_input f, :name, placeholder: "Organization Name", class: "form-control" %>
    <%= error_tag f, :name %>
  </div>

  <div class="form-group">
    <%= inputs_for f, :owner, fn of -> %>
      <%= text_input of, :name, placeholder: "Name" %>
      <%= error_tag of, :name %>
      <%= text_input of, :email, placeholder: "Email" %>
      <%= error_tag of, :email %>
      <%= password_input of, :password, placeholder: "Password" %>
      <%= error_tag of, :password %>

    <% end %>
  </div>
  <%= submit "Create Organization", class: "btn btn-primary" %>
<% end %>

Pavel Pavel · Accepted Answer · 2017-09-24T18:34:27

It is appeared that Ecto.Multi is not hard to use for my case.

Here is what I've did and it worked perfectly

changeset = %Organization{} |> Organization.registration_changeset(params)

multi = Multi.new
|> Multi.insert(:organization, changeset)
|> Multi.run(:user, fn %{organization: organization} ->
  organization
  |> Repo.preload(:users)
  |> Changeset.change
  |> Changeset.put_assoc(:users, [organization.owner])
  |> Repo.update
end)

case Repo.transaction(multi) do
  {:ok, %{organization: organization}} ->
    conn
    |> put_flash(:info, "#{organization.name} created!")
    |> redirect(to: organization_path(conn, :show))
  {:error, :organization, changeset, %{}} ->
    render(conn, "new.html", changeset: changeset)
end

Save one model in multiple associations for parent object at once

1 Answers