Am not able create variable using macro in Data step using SAS

Question

data freq;;
    input placebo ;
    cards;
3
    ;
Run;


data freqt;
    set freq;
        %macro freq1 (arm=,pct=,result=);
            %if &arm ne . %then &pct=&arm*100;
        %if &pct ne .  %then %do;
            %if &pct le 10 %then &result = "test";
        %end;
        %mend freq1;
        %freq1(arm=placebo,pct=pct_pla,result=placebo_);
run;

Above data step macro If then conditions are not working but normal condition is working but don't need normal condition. Would like use only macro condition. Please help me.

Thank you...

Run your code with options mprint mlogic; and you should be able to see what the error is. — david25272
What are you actually trying to do? Move the macro definition out of the data step as having it there is only going to confuse you. Why would you call the macro with ARM parameter set to a period? What would that mean? — Tom

Tom Tom · Accepted Answer · 2017-07-11T15:33:56

Hard to tell what you want to do. But to develop a macro you need to first start with working SAS code. Perhaps something like:

data freqt;
  set freq;
  if placebo ne . then pct_placebo=placebo*100;
  if . <= pct_placebo <= 10 then placebo_= "test";
run;

Then replace the parts that vary with macro variable references.

%let arm=placebo;
...
  if &arm ne . then pct_&arm=&arm*100;
  if . <= pct_&arm <= 10 then &arm._= "test";

Then define a macro.

%macro freq(arm);
if &arm ne . then pct_&arm=&arm*100;
if . <= pct_&arm <= 10 then &arm._= "test";
%mend freq;

Then use the macro. You probably will want to use it multiple times otherwise it wasn't worth the trouble of making a macro to begin with.

data freqt;
  set freq;
  %freq(placebo)
  %freq(drug1)
  %freq(drug2)
run;

Am not able create variable using macro in Data step using SAS

2 Answers