Delphi: declare variable avoiding circular reference

Question

I've got a Delphi unit which needs to keep the pointer of various forms of the application, to do operations on them later.

In order to do those operations, I need to cast the pointer to a form type, ex.

var    
  ptrFrmMain: Pointer;
  CurrentFrmMain: TfrmMain;
begin
    CurrentFrmMain := ptrFrmMain;
    CurrentFrmMain.Close();
end;

The problem is that this unit is contained in the uses of all the other Delphi units of the application. So while I can declare a simple Pointer type in the interface section, I cannot declare a type declared in the other units (such as TfrmMain of the unit frmMain.pas).

I could solve this by placing a use in the implementation section, such as:

interface
type TMyThread = class(TThread)
  Public
    ptrFrmMain:Pointer
...

implementation
    uses frmMain

    var
      CurrentFrmMain: TfrmMain;

but there is still a problem: I need the variable to be specific to my class instance, for multithread purposes, and not a generic global variable. But I cannot place it inside my TmyThread class, since TfrmMain is not declared there and I cannot place it in the uses of the interface section.

A solution would be to place CurrentFrmMain as a local variable in all the procedures which use it and then do the CurrentFrmMain := ptrFrmMain conversion each time, but do you know a better solution?

Thank you very much in advance.

You can typecast your pointer in-place or you can declare as generic base TForm... — Free Consulting
@FreeConsulting I cannot declare as generic base Tform because I need to call functions which are specific of my form, ex. 'CurrentFrmMain.MyFunction()' — Flavio
Declare the variable as a TForm and then cast it to the specific form type using as in the implementation section. This does not "reinitialize" anything, it simply refers to the existing form(s) using a reference of the correct type. — Rudy Velthuis
No, it would not. As checks if the form is really the type of form you specify and throws and exception if not. It is a type safe cast. You can check the type before with is. Also note that as and is only work on objects, not on untyped pointers. — Rudy Velthuis
The general pattern is: if MyForm is TFormABCD then MyFormABCD := MyForm as TFormABCD; // now you can use MyFormABCD. — Rudy Velthuis

Remy Lebeau Remy Lebeau · Accepted Answer · 2016-07-04T19:22:53

I wouldn't put a Form pointer in the thread at all. I would have the thread hold callback functions instead, or even an interface:

type
  TCloseProc: procedure of object;

  TMyThread = class(TThread)
  public
    CloseProc: TCloseProc;
    ...
  end;

...

begin
  if Assigned(CloseProc) then CloseProc();
end;

type
  IMyIntf = interface(IInterface)
  ['{9CC7DB9E-D47F-4B7D-BBF9-6E9B80823086}']
    procedure DoClose;
  end;

  TMyThread = class(TThread)
  public
    Intf: IMyIntf;
    ...
  end;

...

begin
  if Assigned(Intf) then Intf.DoClose();
end;

...

type
  TfrmMain = class(TForm, IMyIntf)
  public
    procedure doClose;
  end;

procedure TfrmMain.doClose;
begin
  Close;
end;

When the thread is created, assign the Form methods to those callbacks, or pass the Form's interface implementation to the thread:

Thread := TMyThread.Create(True);
Thread.CloseProc := frmMain.Close;
Thread.Resume;

Thread := TMyThread.Create(True);
Thread.Intf := frmMain as IMyIntf;
Thread.Resume;

Either way, the thread doesn't need to know about the actual Forms at all while still catering to Form-specific functionality.

Delphi: declare variable avoiding circular reference

2 Answers