forval and varlist loop error

0
votes

I have an Excel file with years in columns C to BQ (1950 to 2016). I read it in via import excel and have a dataset A to BQ, C to BQ being the years.

I´d like to rename C to BQ to _1950 to _2016 via the following loop but seem to have it wrong.

forval  i=1950/2016 {
    foreach x of varlist C-BQ {
        rename `x' _`i+1'
    }
}

C gets renamed to _1950 but Stata throws:

variable _1950 already defined

2
loopsstata

2 Answers

2
votes

You do not need loops: see help rename group for technique. In your case, here's a simplified example.

. ds
A  B  C  D  E

. 
. rename (C-E) _#, addnumber(1950)

. 
. ds
A      B      _1950  _1951  _1952

.

Where you went wrong with your double-loop example is that the innermost loop and outermost loop do not increment in tandem. 

 . forval  i=1950/1952 {
  2. foreach x of varlist C-E {
  3. 
. display `" rename `x' _`i+1' "'
  4. 
.     }
  5. }   
 rename C _1950 
 rename D _1950 
 rename E _1950 
 rename C _1951 
 rename D _1951 
 rename E _1951 
 rename C _1952 
 rename D _1952 
 rename E _1952

.

1
votes

There are two problems here. You need a single loop and the syntax for incrementing the local macro is quite wrong.

The syntax 

`i+1'

is not equivalent to the value of the local macro i plus 1.

Try it: 

. local i = 42

. di "`i+1'"
42

What's happening is that Stata ignores the +1 within the macro reference as trailing garbage, but it does show what's in the macro i: it can make sense of that reference. The rule applying here is that the + could not be part of a legal macro name.

You could do this to take the local macro, add 1, and show the result: 

. di "`=`i'+1'"
43

See the help for macro.

As William Lisowski points out, rename will do the renaming for you any way without an explicit loop.

But how would you loop if you did not know that, or if you were using a version of Stata that did support loops but not the extra rename facilities introduced in Stata 12? Here's one way: 

local i = 1950 
foreach x of varlist C-BQ {
    rename `x' _`i'
    local ++i 
}

Another way to do it before Stata 12 would be to use renvars from the Stata Journal 

renvars C-BQ \ _1950-_2016

renvars requires Stata 8 up. Naturally, underneath the surface it is executing a loop over your old variables and your new variable names.