How to merge or copy a column from specific worksheets in multiple workbooks to a new workbook?

Question

I would like to copy column A from worksheet X of workbook 1 (up to workbook 100) and column A from worksheet Y of the same workbooks to a new workbook or to an open and empty workbook. The column from sheet X should be copied to column A of the specific sheet Xmerge and the column from sheet Y should go to column A of the specific sheet Ymerge in the new workbook. Additional copied columns should be inserted to columns from left to right, respectively next to column A and then B, C etc.

Since there are a lot of workbooks which I have to consider I would like to automate this process with a VBA macro.

Details: All workbooks are in one folder. The amount of filled cells in the different columns is not equal and some cells can contain no or error data. I use Excel 2010.

I tried to modify the following macro code to suit my needs, unfortunately without success. (source: https://msdn.microsoft.com/en-us/library/office/gg549168(v=office.14).aspx)

This macro copies rows to rows instead of columns to columns. Therefore I suppose that some changes in this macro would solve the problem. But irrespective of this macro I would be grateful for every good help.

Sub MergeAllWorkbooks()
Dim SummarySheet As Worksheet
Dim FolderPath As String
Dim NRow As Long
Dim FileName As String
Dim WorkBk As Workbook
Dim SourceRange As Range
Dim DestRange As Range

' Create a new workbook and set a variable to the first sheet. 
Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)

' Modify this folder path to point to the files you want to use.
FolderPath = "C:\Users\Peter\invoices\"

' NRow keeps track of where to insert new rows in the destination workbook.
NRow = 1

' Call Dir the first time, pointing it to all Excel files in the folder path.
FileName = Dir(FolderPath & "*.xl*")

' Loop until Dir returns an empty string.
Do While FileName <> ""
    ' Open a workbook in the folder
    Set WorkBk = Workbooks.Open(FolderPath & FileName)

    ' Set the cell in column A to be the file name.
    SummarySheet.Range("A" & NRow).Value = FileName

    ' Set the source range to be A9 through C9.
    ' Modify this range for your workbooks. 
    ' It can span multiple rows.
    Set SourceRange = WorkBk.Worksheets(1).Range("A9:C9")

    ' Set the destination range to start at column B and 
    ' be the same size as the source range.
    Set DestRange = SummarySheet.Range("B" & NRow)
    Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
       SourceRange.Columns.Count)

    ' Copy over the values from the source to the destination.
    DestRange.Value = SourceRange.Value

    ' Increase NRow so that we know where to copy data next.
    NRow = NRow + DestRange.Rows.Count

    ' Close the source workbook without saving changes.
    WorkBk.Close savechanges:=False

    ' Use Dir to get the next file name.
    FileName = Dir()
Loop

' Call AutoFit on the destination sheet so that all 
' data is readable.
SummarySheet.Columns.AutoFit
End Sub

This code is almost right, but as I said before, it copies rows to rows instead of columns to columns. How can I modify it to deal with columns?

Is there a specific problem / question in there? Are you getting an error? Unexpected results? Do you have a question about what one or more of the lines in this code are doing? — CodeJockey
@CodeJockey The specific problem seems to be that it's copying rows to rows instead of columns to columns. — Alex Knauth
@CodeJockey as Alex Knauth mentioned, the code above is correct for copying rows, however I need to copy columns. Do you know how to do this? — Xcell

CodeJockey CodeJockey · Accepted Answer · 2016-05-10T14:40:11

Sample Code Review

To effectively modify the code you have found online, you must first understand what it is doing.

In short, we are iterating over each workbook and performing the following tasks within the loop:

Get the data we want
Print it in our summary sheet, starting with NRow
Increase NRow to the last row of our current data (so that the next group starts in the correct place)

What do we have to do?

In our application, we want to make NRow refer to a column, such that the next data prints to the right instead of below the previous data. Then, when we increment NRow, we need it to count the number of columns in our destination instead of the number of rows. Changes, therefore must occur to the following lines, where NRow occurs:

SummarySheet.Range("A" & NRow).Value = FileName

Set DestRange = SummarySheet.Range("B" & NRow)

NRow = NRow + DestRange.Rows.Count

Our first order of business should be to rename NRow to NCol or something more fitting, since it is no longer counting rows.

Next, let's make our new variable NCol refer to the column to start with instead of the row. I recommend using the Cells function to aid in this. Cells allows us to refer to a cell using index numbers, like Cells(1,2) instead of a string like Range("A2").

SummarySheet.Cells(1, NCol) = FileName ' Prints the fileName in the first row

Set DestRange = SummarySheet.Cells(2, NCol) ' Data starts in second row

Now all that is left to do is to increment NCol based on the number of columns we find instead of the number of rows.

NCol = NCol + DestRange.Columns.Count

By holding the row static and passing NCol as the column, then incrementing NCol based on the number of columns, our data will print sequentially to the right instead of downwards.

As the sample code you've pasted says, you will likely have to determine the size of the range you are taking from the SourceSheet to match your needs. The code above blindly takes A9:C9 You will need to change this to reference the appropriate range in your source (like A1:A12 if you want the first 12 rows in column A).

Note: The code snippets I have written here are for demonstrative purposes ONLY. They have NOT been tested and are NOT intended to simply be copied and pasted into your application.

How to merge or copy a column from specific worksheets in multiple workbooks to a new workbook?

1 Answers