xsl key matching with xpath predicate

Question

I'm learning XML/XSLT/XPATH and have something working a particular way but want to make it more efficient by removing repeat code.

---

XML Sample

<student>
     <scores>
          <score scoreID="1"  weight="10" mandatory="false">7</score>
          <score scoreID="2"  weight="10" mandatory="false">9</score>
          <score scoreID="3"  weight="30" mandatory="true">13</score>
     </scores>
</student>

<student>
     <scores>
          <score scoreID="1"  weight="10" mandatory="false">8</score>
          <score scoreID="2"  weight="10" mandatory="false">4</score>
          <score scoreID="3"  weight="30" mandatory="true">25</score>
     </scores>
</student>

So basically I had some XSL which checks

• if the sum of scores is greater than 25 (i.e half of total weight)
• if mandatory element is true then divide the score by the weight.
• if the result is greater than 0.5; print appropriate result

This was done with the expression below

XSL

<xsl:when test="sum(scores/score) &gt; 25 and scores/score[@mandatory='True' and .div @weight &lt; 0.5]">

This was all well and good except I have many students and many scores and it isn't very efficient as I'm writing the weight and mandatory values under each score.

What I would like to do is declare another structure which has the weight and mandatory attributes and then reference them to each score with keys.

So instead my XML would like more like this (basically without weight and mandatory attributes under each score)

<quizDetails>
      <quiz quizID="1" weight="10" mandatory="false" />
      <quiz quizID="2" weight="10" mandatory="false" />  
      <quiz quizID="3" weight="30" mandatory="true" />
</quizDetails>

<student>
     <scores>
          <score scoreID="1">7</score>
          <score scoreID="2">9</score>
          <score scoreID="3">13</score>
     </scores>
</student>

<student>
     <scores>
          <score scoreID="1">8</score>
          <score scoreID="2">4</score>
          <score scoreID="3">25</score>
     </scores>
</student>

---

What follows is my attempt at doing this

Defining the keys

<xsl:key name ="quizKey" match="quizDetails" use="@quizID" />
<xsl:key name ="weightKey" match="quizDetails" use="@weight" />
<xsl:key name ="mandatoryKey" match="quizDetails" use="@mandatory" />
<xsl:key name ="scoreKey" match="scores" use="@scoreID" />

The conditional test

<xsl:when test="sum(scores/score) &gt; 25 and (key('quizKey', '@quizID') = key('scoreKey', '@scoreID')) and (key('mandatoryKey', 'true') .div (key('weightKey', '@weight') &lt0.5;">

The conditional test is quite a bit off

• I've tried removing the single quotes around the attributes
• I've tried doing a comparison like scoreKey = quizKey
• I've tried simplifying the conditional expression by adding one condition at a time
• I've read and re-read the section on xsl:key in the W3C XSLT2.0 reference

Using the key function is basically my main problem. I want to replicate the behaviour I had with the my previous xml and xsl but without the repeat code.

Answer 1

I think you only really need one key here, to look up the quiz elements

<xsl:key name="quizKey" match="quiz" use="@quizID" />

To look up the quiz element for a current score element, the use of the key would be like this

key('quizKey', @scoreID)

This means your expression needs to look like this:

<xsl:when test="sum(scores/score) &gt; 25 
                and scores/score[number(.) div key('quizKey', @scoreID)[@mandatory='true']/@weight &lt; 0.5]">

You could actually improve things slightly by only selecting mandatory quiz elements in a key though. For example

<xsl:key name="mandatoryKey" match="quiz[@mandatory='true']" use="@quizID" />

Then the condition becomes as follows:

<xsl:when test="sum(scores/score) &gt; 25 
                and scores/score[number(.) div key('mandatoryKey', @scoreID)/@weight &lt; 0.5]">

Answer 2

If I understand this correctly, you only need one key:

<xsl:key name="quiz" match="quiz" use="@quizID" />

Then you can see - from the context of student - if at least one of the scores is mandatory by testing for:

key('quiz', scores/score/@scoreID)/@mandatory='true' 

I am afraid I did not understand what the other test is supposed to do. It looks like it needs to applied to each score individually? But that's not what your original test does.

Note also that XML is case-sensitive: 'True' does not equal to 'true'.

---

Added:

For better clarity, consider the following template:

<xsl:template match="scores">
    <xsl:variable name="total-score" select="sum(score)" />
    <xsl:variable name="total-weight" select="sum(key('quiz', score/@scoreID)/@weight)" />
    <xsl:copy>
        <xsl:for-each select="score">
            <xsl:variable name="quiz" select="key('quiz', @scoreID)" />
            <xsl:if test="$total-score &gt; $total-weight div 2 and $quiz/@mandatory='true' and . div $quiz/@weight &gt; 0.5">
                <xsl:copy-of select="."/>
            </xsl:if>
        </xsl:for-each>
    </xsl:copy>
</xsl:template> 

This outputs an individual score when all of the following conditions are met:

1. the sum of all scores for this student is greater than half of their total weight;
2. the related quiz is mandatory;
3. the score divided by its weight is greater than 0.5.