Convert surface shader to fragment shader

Question

Looking for some help in converting a surface shader to fragment shader. Ultimately to render a texture to a Unity3D Rendertexture. Thanks!

The surface shader outputs noise and is based on https://scrawkblog.com/2013/05/18/gpu-gems-to-unity-improved-perlin-noise/

Here is the surface shader which I'm looking to convert:

Shader "Noise/Diffuse3D"
{
Properties
{
    _MainTex ("Base (RGB)", 2D) = "white" {}
    _Color("Color", Color) = (1,1,1,1)
}
SubShader
{
    Tags { "RenderType"="Opaque" }
    LOD 200

    CGPROGRAM
    #pragma surface surf Lambert vertex:vert
    #pragma target 3.0
    #pragma glsl
    #include "ImprovedPerlinNoise3D.cginc"

    sampler2D _MainTex;
    fixed4 _Color;

    struct Input
    {
        float2 uv_MainTex;
        float3 noiseUV;
    };

    void vert(inout appdata_full v, out Input o)
    {
        UNITY_INITIALIZE_OUTPUT(Input,o);
        //o.noiseUV = v.vertex.xyz; //use model space, not world space for noise uvs
                                  // v.vertex is the input vertex in the vertex shader
        //float3 worldPos = mul(_Object2World, v.vertex).xyz;
        o.noiseUV = mul(_Object2World, v.vertex).xyz;

    }

    void surf(Input IN, inout SurfaceOutput o)
    {
        //uncomment this for fractal noise
        //float n = fBm(IN.noiseUV, 4);

        //uncomment this for turbulent noise
        float n = turbulence(IN.noiseUV, 4);

        //uncomment this for ridged multi fractal
        //float n = ridgedmf(IN.noiseUV, 4, 1.0);

        o.Albedo = _Color.rgb * n;
        o.Alpha = _Color.a;
    }
    ENDCG
}
FallBack "Diffuse"
}

Revick Revick · Accepted Answer · 2016-03-04T15:09:04

Answer from reddit:

 Pass
{
    CGPROGRAM
    #pragma vertex vert
    #pragma fragment frag
    #pragma target 3.0
    #pragma glsl
    #include "ImprovedPerlinNoise3D.cginc"
    #pragma multi_compile_fog

    #include "UnityCG.cginc"

    struct appdata
    {
        float4 vertex : POSITION;
    };

    struct v2f
    {
        float3 noiseUV : TEXCOORD0;
        UNITY_FOG_COORDS(1)
        float4 vertex : SV_POSITION;
    };

    fixed4 _Color;
    v2f vert (appdata v)
    {
        v2f o;
        UNITY_INITIALIZE_OUTPUT(v2f,o);
        o.vertex = mul(UNITY_MATRIX_MVP, v.vertex);
        o.noiseUV = mul(_Object2World, v.vertex).xyz;
        UNITY_TRANSFER_FOG(o,o.vertex);
        return o;
    }

    fixed4 frag (v2f i) : SV_Target
    {

        //uncomment this for fractal noise
        //float n = fBm(i.noiseUV, 4);

        //uncomment this for turbulent noise
        float n = turbulence(i.noiseUV, 4);

        //uncomment this for ridged multi fractal
        //float n = ridgedmf(i.noiseUV, 4, 1.0);
        fixed4 col = _Color;
        col.rgb*=n;
        UNITY_APPLY_FOG(i.fogCoord, col);
        return col;
    }
    ENDCG
}
}
FallBack "Diffuse"

Convert surface shader to fragment shader

1 Answers