neo4j - match nodes and add relationships to them

Question

how do i add relationships to nodes returned by a cypher query?

I have written a query that returns me all the person nodes who have the same surname who live at the same address. I now want to add a relationship between these person nodes to indicate they are the same person. The query below returns me 3 person nodes and I want to add a relationship from the first node (returned by the ORDER BY) to the other 2.

MATCH (a:Address) <-[LIVES_AT]-(p:Person)
WITH a as addnode, p.surname as psurname,  COUNT(p.name_urn) as c
WHERE c > 1
MATCH (a2:Address{address_urn:addnode.address_urn})<-[LIVES_AT]-  (p2:Person{surname:psurname})
WITH p2 as p2node
ORDER BY CASE
         WHEN p2node.master_record = 'Y' 
         THEN 
           1
         ELSE
           2
         END
WITH collect(p2node) as colp2node
RETURN colp2node

Hope this makes sense? Please advise if there is a better way of doing this.

cybersam cybersam · Accepted Answer · 2016-01-07T19:42:25

Something like this should work for you:

MATCH (a:Address)<-[LIVES_AT]-(p:Person)
WITH a, p.surname AS psurname, COUNT(p.name_urn) AS c
WHERE c > 1
MATCH (a2:Address { address_urn:a.address_urn })<-[LIVES_AT]-(p2:Person { surname:psurname })
WITH p2
ORDER BY CASE WHEN p2.master_record = 'Y' THEN 1 ELSE 2 END 
WITH collect(p2) AS colp2
WITH colp2[0] AS master, colp2[1..] AS others
UNWIND others AS other
MERGE (master)-[:HAS_ALIAS]->(other);

I use MERGE to avoid duplicate relationships.

By the way, just because two people have the same surname and live at the same address, that does not normally mean they are the same person. I hope you are sure that what you are doing is appropriate.

neo4j - match nodes and add relationships to them

1 Answers