Getting "Bad Request. Invalid request header"

Question

Below is the code I use for VBScript to send an HTTP request.

Option Explicit

Dim objHTTP, url, Hpost
Set objHTTP = CreateObject("Microsoft.XMLHTTP")    
url = "http://localhost:8080/xyz/processKey?key=abcd"
objHTTP.open "POST", url, False
objHTTP.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
objHTTP.send
WScript.Echo objHTTP.responseText

Error:

HTTP 400 Bad Request
Content-Length must be > 0

Shouldn't it be Set http = CreateObject("Microsoft.XmlHttp")? I know it's mostly case insensitive but I don't think that extends to objects. — scrappedcola
It does not matter. I tried both "Microsoft.XmlHttp" and ""Microsoft.XMLHTTP" but still getting same 400 erro. — rrr ppp
CreateObject is not case-sensitive, but Microsoft.XMLHTTP is outdated and should be replaced by Msxml2.XMLHttp. The code worked for me either way, though. What does the server log say about the failed requests? — Ansgar Wiechers
I do not have access to the server.I replaced it with Msxml2.XMLHttp but still getting 400 error code , Bad Request.Content-Length must be >0 — rrr ppp
I quess that send method requires a parameter, cf. How To Submit Form Data by Using XMLHTTP or ServerXMLHTTP Object. — JosefZ

Stephen Quan Stephen Quan · Accepted Answer · 2015-12-08T13:41:01

[Edit: Adopting @Lankymart's comments]

Your request doesn't appear to be a pure "HTTP POST" or "HTTP GET" request.

For a "HTTP POST" request:

Parameters shouldn't be in the URL, it should be in the body
Seems the server is expecting a Content-Length

Example:

Option Explicit
Dim objHTTP, url, param
Set objHTTP = CreateObject("Microsoft.XMLHTTP")    
url = "http://localhost:8080/xyz/processKey"
param = "key=abcd"
objHTTP.open "POST", url, False
objHTTP.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
objHTTP.send param
WScript.Echo objHTTP.responseText

For a "HTTP GET" request

Parameters must be embedded in the URL
Send must be blank

Example:

Option Explicit
Dim objHTTP, url, param
Set objHTTP = CreateObject("Microsoft.XMLHTTP")    
url = "http://localhost:8080/xyz/processKey"
param = "key=abcd"
objHTTP.open "GET", url + "?" + param, False
objHTTP.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
objHTTP.send
WScript.Echo objHTTP.responseText

Getting "Bad Request. Invalid request header"

1 Answers