Facts, Predicates and Rules

Question

I decided to study prolog just for fun, I'm watching some video tutorials. Also I searched on the internet some problems to try to solve, but Can't find a way to solve this.
I was able to solve this puzzle on paper, but I can't pass it into code.

The problem:

I have 8 candidates (Lia, Mel, Nanda, Olga, Rute, Sara, Tina, Pilar).
They will all be tested from Monday to Friday on the time 8:00 and 9:00.

And I have some rules like:

Sara HAS TO be tested on Wednesday at 9.
No girl will be tested on Wednesday at 8.
Pilar HAS TO tested BEFORE Nanda.
Olga HAS TO be tested in same day of Mel.
IF Lia is tested at 8 of any day, so Rute HAS TO be tested at 8 in a different day.

I don't want full solution, I just want some help to start with this.

I was trying to write something but without success.

%   Facts   %
candidate(lia).
candidate(mel).
candidate(nanda).
candidate(olga).
candidate(pilar).
candidate(rute).
candidate(sara).
candidate(tina).

day(monday).
day(tuesday).
day(wednesday).
day(thursday).
day(friday).

time(8).
time(9).  

/*Sara HAS TO be tested on Wednesday at 9*/
tested_on(sara, wednesday, 9).  

/*No test will happen on Wednesday at 8*/
no_test(X, wednesday, 8) :- X == none.  

I was even trying to build a struct

cand(
    sara,
    date(wednesday, 9)
    ).  

After that my program would have to answer some questions like:

Which would be the right list of candidates to be tested on 8:00 from monday to friday ?

My main idea was to start writing the rules and facts then I'd go through all the rules testing each one. But I can't even write the facts and rules right...

Answer 1

Prolog is a declarative language. Focus on a clear description of what holds about every solution. The Prolog system will do the rest for you. Do not say: "I'd go through all the rules testing each one". Better say: "I state the properties that hold for every solution." This is because, when you are done, your predicate can be used in several directions: Yes, you can use it for testing a given solution. But you can also use it to generate solutions, and to complete partially filled schedules, if possible.

Begin with:

schedule(S) :- ...

This is read as: S is a schedule if ... . Now, fill in the dots: Which properties hold in any valid schedule? These are the constraints that are given in your task, stated in Prolog as goals.

As you wish, I do not give you a full solution, but a few hints to get you started. I am using CLP(FD) constraints to declaratively state all requirements. The code runs, with at most minor modifications, in SICStus, SWI, YAP, GNU Prolog and several other systems.

First, to represent the available time slots, I use integers 0..9. Specifically, I use:

       Monday  Tuesday  Wednesday Thursday Friday
8:00:    0        2         4        6       8
9:00:    1        3         5        7       9

For example, Thursday 9:00 is denoted by the integer 7.

Each candidate is a finite domain variable that denotes the time slot the candidate is assigned.

I represent a schedule as a list of time slots, one for each candidate, in the order they are stated in the task description.

It only remains to encode the specified constraints, using CLP(FD) predicates. Check out your Prolog system's documentation to see what these predicates mean. For example, for SICStus Prolog, check out membership constraints and arithmetic constraints. Likewise for other systems.

Here is a start:

:- use_module(library(clpfd)).

schedule(Vars) :-
        Vars = [Lia,Mel,Nanda,Olga,Rute,Sara,_Tina,Pilar],
        all_different(Vars),
        Vars ins 0..9,
        Sara #= 5,
        maplist(#\=(4), Vars),
        Pilar #< Nanda.

As you see, this closely corresponds to the constraints that appear in the task description. For example, Sara can only be scheduled on Wednesday at 9:00, and, according to the above table, this specific time slot corresponds to the integer 5, and the variable Sara denotes at which time slot Sara is scheduled. Therefore, we state the constraint Sara #= 5. Similarly, no one can be scheduled on Wednesday at 8:00. This time slot corresponds to the integer 4, and so we state the constraint maplist(#\=(4), Vars), which is true if and only if each variable in Vars is not equal ((#\=)/2) to 4.

I leave encoding the final two constraints as an exercise for you. Try to encode them nicely and compactly.

Sample solution with the encoded constraints:

?- Vs = [Lia,Mel,Nanda,Olga,Rute,Sara,Tina,Pilar], schedule(Vs), label(Vs).
Vs = [0, 1, 3, 7, 6, 5, 8, 2],
Lia = 0,
Mel = 1,
Nanda = 3,
Olga = 7,
Rute = 6,
Sara = 5,
Tina = 8,
Pilar = 2 .

Note that, coincidentally, this satisfies even the last constraint, which we did not yet encode explicitly.

Answer 2

To ease the date comparison, a small change of representation is handy:

candidate(1,lia).
candidate(2,mel).
candidate(3,nanda).
candidate(4,olga).
candidate(5,rute).
candidate(6,sara).
candidate(7,tina).
candidate(8,pilar).

day(1,monday).
day(2,tuesday).
day(3,wednesday).
day(4,thursday).
day(5,friday).

then we can represent the solution as a list of pairs (Date,Time), where the position in the list represent the girl:

solution(Dom) :-
    Dom = [
        (D1,T1),
        (D2,T2),
        ...
        (D8,T8)
    ],
dom(Dom),
...

the domain generation is a bit tricky: we must get all distinct pairs of Day,Time. A first, inefficient approach

dt((D,T)) :- day(D,_),time(T).

dom([]).
dom([E|R]) :- dt(E), dom(R), \+ memberchk(E, R).

?- length(L,6),time(aggregate(count,so:(L^dom(L)),N)).
% 10,044,119 inferences, 3.188 CPU in 3.190 seconds (100% CPU, 3150577 Lips)
L = [_G6035, _G6038, _G6041, _G6044, _G6047, _G6050],
N = 151200.

while this alternative is faster

dom([E]) :- dt(E).
dom([E|R]) :- dom(R), dt(E), \+ memberchk(E, R).

?- length(L,6),time(aggregate(count,so:(L^dom(L)),N)).
% 952,236 inferences, 0.567 CPU in 0.567 seconds (100% CPU, 1680621 Lips)
L = [_G6041, _G6044, _G6047, _G6050, _G6053, _G6056],
N = 151200.

(dom/1 works for any length, I've chosen 6 to exemplify...)

now the constraints can be expressed, for instance

% Sara HAS TO be tested on Wednesday at 9.
day(D6, wednesday), T6 = 9,

The constraint

No girl will be tested on Wednesday at 8.

can be tricky: it means that the pair (3,8) cannot appear in Dom. But it become easy using if/then/else construct.

Let me know if you need more clue.