Why won't my macro variable resolve?

9
votes

I have a macro variable, &myvar, but it won't resolve when I try to put it in a data step variable. Why won't it, and what can I do to fix this?

%let myvar=Hello, world;
data _null_;
  x='&myvar.';
  put x=;
run;
2
sassas-macro
This is intended to be used to close questions as duplicate where the only problem is single/double quoting macro variables. If someone else finds a good already existing one I'm happy to use that, but I could find one that didn't have other complexities to it that might have been confusing. – Joe
@NEOmen In some cases it is easier to create a 'dummy' question that has less complexity than other questions but nonetheless answers something that comes up frequently and then use it as a close-as-duplicate. The 'dummy' question should still be technically a good question on its own (as this is) but isn't of course asked for the purpose of finding out information :) – Joe

2 Answers

12
votes

Macro variables in SAS won't resolve when they are in single quotes, '&myvar'. They need to be in double quotes, "&myvar", in order to resolve properly.

If you need to have single quotes and a resolved macro variable, you have a few options, but the simplest is:

%str(%'&myvar.%')

The %' inside of %str will place a single quote character (or apostrophe) in the text string by itself without causing it to be quoted.

data _null_;
  x="%str(%'&myvar.%')";
  put x=;
run;

or

%let myvar2 = %str(%'&myvar.%');
1
votes

In SAS 9.4M6 or higher version, you can use %tslit() to achieve the same function.

%let myvar=Hello, world;
data _null_;
  x=%tslit(%superq(myvar));
  put x=;
run;

%put %tslit(%superq(myvar));

x=Hello, world
'Hello, world'

This is a macro pre-defined in SAS. Here is the documentation about it:
https://documentation.sas.com/?docsetId=lebaseutilref&docsetTarget=n1phgnraoodvpln1bm941n44yq7q.htm&docsetVersion=9.4&locale=en