Concatenate two given strings in 8086 + MOVSB does not work

Question

I'm trying to write a 8086 assembly program to concatenate two given strings. In order to do this, I used a "REP MOVSB" instruction, but the program didn't work well. So I wrote a program that should statically concatenate two strings, but it seems that "REP MOVSB" does not affect on strings at all. Here's the part of code I wrote for test:

                                          
data    segment

string1 db  "Lotfi", 0
string2 db  "Ali ", 0 

data ends


code segment    

ASSUME  CS: code, DS: data

start:
    cld
    mov     ax  , data
    mov     DS  , ax

    mov     SI  , offset string1
    mov     DI  , offset string2
    add     DI  , 3 ; Adding the length of destination string to the DI


    mov     cx  , 5
    rep movsb ; This should concat two strings

    ; Printing the result character by character on the console
    mov     SI  , offset string2
l:  lodsb           ; Printing loop
    mov dl, al
    mov ah, 2h
    int 21h
    jmp l


    hlt 

    code ends
end start

The result of the code is something like:

Ali             ü,Z0???... (And so)

What's wrong with my code? Tanx

Random notes: 1) Your loop is infinite. 2) There's no allocated memory after the end of String2. 3) After the concatenation the resulting string isn't null-terminated. 4) Just in case: Are you sure your code operates in a 16bit environment? If it's 32bit you have random garbage in upper 16 bits of all registers. — Ondrej Tucny
Thank you, I considered all of your recommendation in my real program (except the last one about 16 and 32 bit, which I didn't get it!), But here I deleted them all for making it easier to read — AliLotfi
@OndrejTucny considering there are calls to the DOS kernel (int 21h) I think it's safe to assume the code runs in a 16-bit environment. — davmac
@davmac "I have… seen things you people wouldn't believe…" (However, yes it's safe to assume.) — Ondrej Tucny
This method could, theoretically, overwrite data in memory. Better to reserve a buffer in memory, and concatenate the strings in the reserved space. — Andrew Hardiman

davmac davmac · Accepted Answer · 2014-12-21T12:12:49

movsb moves from DS:SI to ES:DI. You've loaded the DS but not the ES register.

You need only add a single line:

cld
mov     ax  , data
mov     DS  , ax
mov     ES  , ax   ; here!

Concatenate two given strings in 8086 + MOVSB does not work

3 Answers