How to generate Histograms graph on time series in SAS using proc template

Question

I have a data set that containing two time series data. One is y, the other is predicted y. I want to draw a overly histogram graphic for the two series in one graph.

data a;
input y haty;
datalines;
2    2.1
2.12 2.24
2.3  2.5
3.1  3.1
1.23 0.98
;
run;

I have a sample code for Defining a Template That Overlays Two Histograms.

proc template;
define statgraph dualhist;
   begingraph;
   entrytitle "Graph"; /** optional title **/
   layout overlay / xaxisopts=(label="Length");
      /** first plot: a histogram **/
      histogram y / name="Y"
          binwidth=5; 
      /** second plot: a semi-transparent histogram **/
      histogram haty / name="Predicted Y"
          binwidth=5 datatransparency=0.7
          fillattrs=(color=GraphData2:color);
      /** optional: add legend by specifying names **/
      discretelegend "y" "haty";
   endlayout;
   endgraph;
end;
run;

proc sgrender data=a template=dualhist;
run;

I need some help on the statgraph, especially for the x axis. I want y axis to be the value of y and haty.

I do not understand your question: in a histogram the x axis is the value of the variable and the y axis is its frequency/density. Or do you want the histogram bars to be horizontal? Also, histograms are rarely useful for time-series as they completely lose the timing information. — Aniko

SRSwift SRSwift · Accepted Answer · 2014-10-12T21:35:11

It's not clear what you want but here are some examples that may help.

/* SIMPLE HISTOGRAM */
/* Overlayed histogram with counts. 
    Custom intervals can be set with the binstart= and 
    binwidth= options  */
proc sgplot data = a;
    histogram y/ scale = count;
    histogram haty / transparency = 0.7 scale = count;
run;

/* VIRTICAL HISTOGRAM */
/* Use proc univariate to bin data */
proc univariate data = a noprint;
    histogram haty y / noplot outhistogram = b;
run;
/* Get the counts for each variable in a separate column */
data c;
    merge 
        b (where = (_var_ = "y")) 
        b (where = (_var_ = "haty") rename = (_count_ = _count_hat));
    by _midpt_;
    drop _var_ _obspct_;
run;
/* Plot the histogram on its with horizontal counts */
proc sgplot data = c;
    hbar _midpt_ / 
        response = _count_ 
        legendlabel = "Y" 
        barwidth = 1;
    hbar _midpt_ / 
        response = _count_hat 
        legendlabel = "Predicted Y"  
        barwidth = 1
        transparency = 0.7;
    xaxis  integer;
run;

/* BAR CHART OF DATA */
/* This should be a scatter or series plot, not bars! */
/* Add an id variable */
data d;
    set a;
    ID = _N_;
run;
proc sgplot data = d;
    vbar ID / response = y;
    vbar ID / response = haty transparency = 0.7;
run;

How to generate Histograms graph on time series in SAS using proc template

1 Answers