How to let gradle build dependent sub-project first when using non-compile dependencies

Question

How can I tell gradle to build a certain sub-projects first, even though I don't have a compile dependency to them? How are project dependencies handled internally?

Example:

settings.gradle:

include "app", "schema"

build.gradle:

allprojects {
  apply plugin: 'java'
}

schema/build.gradle:

// empty

app/build.gradle:

configurations {
    schemas
}

dependencies {
    schemas project(":schema")
    schemas "org.example:example-schema:1.0"
}

task extractSchema(type: Copy) {
    from {
        configurations.schemas.collect { zipTree(it) }
    }
    into "build/schemas"
}

//compileJava.dependsOn extractSchema

And when running:

$ cd app
$ gradle extractSchema

I get:

Cannot expand ZIP 'schema/build/libs/schema.jar' as it does not exist.

What I want is that gradle automatically builds all sub-projectes defined in the configurations.schemas dependency list first (if they are projects).

Note: I want to be able to share the extractSchema task across multiple gradle projects, so it is important that gradle takes the list of sub-project to be built first from the configurations.schemas list.

Thanks

Have you read gradle.org/docs/current/userguide/multi_project_builds.html? You could make extractSchema dependent on the tasks that generate the schemas, e.g. task extractSchema(type: Copy, dependsOn: ':schema:assemble') — Leonard Brünings
But the thing is that I don't want to hardcode the dependency. Gradle should be able to resolve the dependency from the configurations.schemas list automatically and resolve/build them first. — sebdehne
Maybe you can use gradle.org/docs/current/dsl/… for your depends on, based on the configuration. — Leonard Brünings

Peter Niederwieser Peter Niederwieser · Accepted Answer · 2014-08-07T14:03:12

Gradle build order is never on the project level, but always on the task level. from(configuration.schemas) would infer task dependencies automatically, but in case of from(configuration.schemas.collect { ... }), this doesn't work because the resulting value is no longer Buildable. Adding dependsOn configurations.schemas should solve the problem.

How to let gradle build dependent sub-project first when using non-compile dependencies

1 Answers