Set 'From' email address in Lotus Notes when sending via VBA

Question

I am using a VBA function in an Access database to call Lotus Notes to send automated emails to customers. The emails are being sent from the users personal Lotus account so that they have a history of the sent emails in their Sent items. However, I don't want the customers to see our internal email addresses.

We are instructing the customers not to reply to the email (call us instead) and want the email to appear to be from [email protected]. I am able to set the 'ReplyTo' field to something like [email protected] which works if the customer replies to the email but the 'From' field still appears to be coming from the users real email address and the customer would be able to see that information and still send an email to our address.

I have tried setting the following properties, but they don't seem to work:

.DisplaySent = "[email protected]"
.iNetFrom = "[email protected]"
.iNetPrincipal = "[email protected]"

(I currently have these commented out in the below VBA because they didn't seem to have any effect)

Below is the VBA I am using. Any suggestions? Thanks!

Public Sub SendNotesMail(Subject As String, Attachment As String, Recipient As     Variant, BodyText As String, SaveIt As Boolean)

    'Set up the objects required for Automation into lotus notes
    Dim Maildb As Object 'The mail database
    Dim UserName As String 'The current users notes name
    Dim MailDbName As String 'THe current users notes mail database name
    Dim MailDoc As Object 'The mail document itself
    Dim AttachME As Object 'The attachment richtextfile object
    Dim Session As Object 'The notes session
    Dim EmbedObj As Object 'The embedded object (Attachment)

    'Start a session to notes
    Set Session = CreateObject("Notes.NotesSession")

    'Next line only works with 5.x and above. Replace password with your password
    'Session.Initialize ("password")
    'Get the sessions username and then calculate the mail file name
    'You may or may not need this as for MailDBname with some systems you
    'can pass an empty string or using above password you can use other mailboxes.
    UserName = Session.UserName
    MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"

    'Open the mail database in notes
    Set Maildb = Session.GETDATABASE("", MailDbName)
    If Maildb.ISOPEN = True Then
        'Already open for mail
    Else
         Maildb.OPENMAIL
    End If

    'Set up the new mail document
    Set MailDoc = Maildb.CREATEDOCUMENT
    MailDoc.principal = "[email protected]"
    MailDoc.ReplyTo = "[email protected]"
    'MailDoc.DisplaySent = "[email protected]"
    'MailDoc.iNetFrom = "[email protected]"
    'MailDoc.iNetPrincipal = "[email protected]"
    MailDoc.Form = "Memo"
    MailDoc.sendto = Recipient
    MailDoc.Subject = Subject
    MailDoc.Body = BodyText
    MailDoc.SAVEMESSAGEONSEND = SaveIt

    'Set up the embedded object and attachment and attach it
    If Attachment <> "" Then
        Set AttachME = MailDoc.CREATERICHTEXTITEM("Attachment")
        Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment, "Attachment")
        MailDoc.CREATERICHTEXTITEM ("Attachment")
    End If

    'Send the document
    MailDoc.PostedDate = Now() 'Gets the mail to appear in the sent items folder
    MailDoc.SEND 0, Recipient

    'Clean Up
    Set Maildb = Nothing
    Set MailDoc = Nothing
    Set AttachME = Nothing
    Set Session = Nothing
    Set EmbedObj = Nothing
End Sub

umeli umeli · Accepted Answer · 2014-05-16T14:41:02

You can't change the From this way. It will always be sent with the original sender.

There are two ways to solve this. No. 1 create a Mailbox for [email protected] and send all the mails from that box instead the user's. All the mails will then have a flag "sent by" to original sender. Depending on the mailclient, a reply will end either in the central mailbox or in the users box.

No. 2 you create the mail directly in the servers mail.box, than you are able to manipulate all the fields. And afterwards you create the same document in the users mailbox with all the necessary items for sent mails.

Set 'From' email address in Lotus Notes when sending via VBA

2 Answers