Axis marks command in Gnuplot not working?

Question

I have a mulit-plot that doesn't look pretty, which is supposed to go into a physics paper. Although I am having lots of issues as you can see, the most frustrating is that it seems that Gnuplot is outright disobeying my set ytics commands on some of the subplots. Also, my axis labels for the first plot are ending up on the second plot instead. How do I solve these problems of Gnuplot having a mind of its own and refusing to do what I say?

reset
set terminal postscript eps enhanced color size 10,5
set output 'C:\\Users\\cole1\\Desktop\\multiplot3.eps'
set multiplot
set xtics font "Times-Roman, 20"
set ytics font "Times-Roman, 18"

set size .5,.25
set origin 0,.75
set label "(a)" at screen .06,.95
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\logefficiency1.txt' using 1:2 lc rgbcolor "#FF0000" pt 5 with lp notitle
set ytics -3,1,2
set xlabel "Log_{10} current density factor"
set ylabel "Log_{10} percent efficiency"
unset label 1


set size .5,.25
set origin .5,.75
set label "(b)" at screen .56,.95
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4009.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,0.5,1
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


set size .5,.25
set origin 0,.5
set label "(c)" at screen .06,.7
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4018.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,1,4
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


set size .5,.25
set origin .5,.5
set label "(d)" at screen .56,.7
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4027.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,15,60
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


set size .5,.25
set origin 0,.25
set label "(e)" at screen .06,.45
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4036.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,15,60
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


set size .5,.25
set origin .5,.25
set label "(f)" at screen .56,.45
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4045.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,15,60
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


set size .5,.25
set origin 0,0
set label "(g)" at screen .06,.2
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4054.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,30,120
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


set size .5,.25
set origin .5,0
set label "(h)" at screen .56,.2
plot 'C:\\Users\\cole1\\Documents\\MATLAB\\spectralinfo4063.txt' using 1:2 lc rgbcolor "#0000FF" with lines notitle
set ytics 0,300,1200
set xlabel "Frequency(THz)"
set ylabel "Intensity/ freq. interval (arb.)"
unset label 1


unset xtics
unset ytics
unset multiplot

How can we see that you have a lot of issues? You don't show any image with the current output... All settings for one subplot must be done before the actual plot command. That may be the main problem. Have a look at the syntax set multiplot layout 4,2 for a simplification of your actual script — Christoph
In order for anyone to help you fix the problem, you need to provide some test data, or at least an image showing what's wrong. — Tom Fenech
The fact I had things after the plot command was the whole problem and it's fixed now. Thanks Christoph! — user3128107

Christoph Christoph · Accepted Answer · 2014-03-15T13:06:48

The ytic settings work only if placed before the plot command. That applied to all settings. Everything which must appear in a graph and all the settings must be done before the respective plot command:

set ytics 1
plot x

Here is an improved version of your script:

reset

datadir = 'C:\\Users\\cole1\\Documents\\MATLAB\\'

set terminal postscript eps enhanced color size 10,5
set output 'multiplot3.eps'

set xtics font "Times-Roman, 20"
set ytics font "Times-Roman, 18"

set style line 1 lc rgb "red" pt 5
set style line 2 lc rgb "blue"

set style data lines
unset key

set multiplot layout 4,2

set label 1 "(a)" at graph 0.01,0.9
set ytics 1
set xlabel "Log_{10} current density factor"
set ylabel "Log_{10} percent efficiency"
plot datadir.'logefficiency1.txt' ls 1 with lp

set label 1 "(b)"
set ytics 0.5
set xlabel "Frequency (THz)"
set ylabel "Intensity / freq. interval (arb.)"
plot datadir.'spectralinfo4009.txt' ls 2

set label 1 "(c)"
set ytics 1
plot datadir.'spectralinfo4018.txt' ls 2

set label 1 "(d)"
set ytics 15
plot datadir.'spectralinfo4027.txt' ls 2

set label 1 "(e)"
plot datadir.'spectralinfo4036.txt' ls 2

set label 1 "(f)"
plot datadir.'spectralinfo4045.txt' ls 2

set label 1 "(g)"
set ytics 30
plot datadir.'spectralinfo4054.txt' ls 2

set label 1 "(h)"
set ytics 300
plot datadir.'spectralinfo4063.txt' ls 2

unset multiplot

The main points are:

Use set multiplot layout 4,2 to have the size and the origin changed automatically.
You must set the xlabel and ylabel only once if they don't change.
Likewise you must use set ytics only if the settings change.
Usually, if you have autoscaling enabled, you must not specify start and end of the ytics, but only the increment.
For the subfigure label use coordinates relative to the actual plot (graph 0.01,0.9). And use always the same label id (1). Then for the second and all following plots you must change only the text, the old coordinates are used. Then you can do the fine-tuning of the label position at only one position in the code.
Use set style data lines
Use line styles
Use unset key to hide the legend.

Axis marks command in Gnuplot not working?

1 Answers