Actionscript 3, Flash CC: Placing Objects In An Array From The Library Onto The Stage

Question

Hello programming gurus of stackoverflow, I am hoping that at least one of you will be able to help me with my coding problem. This is the first time I'm posting on this site, so if I miss something with the structure of my post, or anything please let me know (preferably not in a condescending matter) and I will gladly change it.

I actually had a different problem I was going to ask about, but I recently realized that some objects from my library weren't showing up on my stage. Hopefully, if this gets solved I won't have my other problem.

I am creating a learning module app using Flash CC and Actionscript 3, I like to think I am fairly proficient with Flash, but right now all my code is on the timeline because when I started I wasn't aware of the package setup. When I finish with the learning module I'll try and move everything to an AS package, so please bear with me.

This current frame of the module is a drag and drop game where the user drags the correct food, for the animal they chose in the previous frame, to the animal in the middle. The animal is dynamically placed on the stage, as well as an array of six possible food choices, all MovieClips pulled from the library. The array of food elements is actually not what I'm having problem with, they appear on my stage with no problems at all. The problem I'm having is when the user drags the correct food onto the animal, and the win condition is met, the array of balloon elements does not show up on the stage. I find it weird because I'm using near identical code for both the food and balloon array.

Here is my full code:

import flash.display.MovieClip;
import flash.events.MouseEvent;

foodPet();

function foodPet():void {
    //all of my pet, food, and balloon library objects have been exported for AS
    var theBird:pet_bird = new pet_bird;
    var theCat:pet_cat = new pet_cat;
    var theChicken:pet_chicken = new pet_chicken;
    var theDog:pet_dog = new pet_dog;
    var theDuck:pet_duck = new pet_duck;
    var theGuinea:pet_guinea = new pet_guinea;
    var theHamster:pet_hamster = new pet_hamster;

    var birdSeed:food_bird_seed = new food_bird_seed;
    var catFood:food_cat_food = new food_cat_food;
    var chickenFeed:food_chicken_feed = new food_chicken_feed;
    var chocolate:food_chocolate = new food_chocolate;
    var dogFood:food_dog_food = new food_dog_food;
    var duckFood:food_duck_food = new food_duck_food;

    var animalList:Array = [theBird, theCat, theChicken, theDog,
        theDuck, theGuinea, theHamster];
    var food1Array:Array = [birdSeed, catFood, chickenFeed,
        chocolate, dogFood, duckFood, 4];
    var xPosFood:Array = new Array();
    var yPosFood:Array = new Array();
    xPosFood = [32, 71, 146, 363, 431, 512];
    yPosFood = [304, 222, 123, 123, 222, 304];
    var animalClip:MovieClip;
    animalClip = animalList[chosenAnimal];
    addChild(animalClip);
    animalClip.x = 256;
    animalClip.y = 287;
    animalClip.name = "selectedAnimal";

    for (var i:uint = 0; i < food1Array.length - 1; i++){ //Where the food gets added
        var isItRight:Boolean = false;
        var foodName:String = ("food" + i);
        var foodClip:MovieClip;
        foodClip = food1Array[i];
        foodClip.x = xPosFood[i];
        foodClip.y = yPosFood[i];
        foodClip.name = foodName;
        addChild(foodClip);
        trace(foodClip.parent);
        foodDragSetup(foodClip, animalClip, food1Array[food1Array.length - 1], isItRight);
    }
}

function foodDragSetup(clip:MovieClip, targ:MovieClip, correctNum:uint, isItRight:Boolean) {
    var beingDragged:Boolean = false;
    var xPos:Number = clip.x;
    var yPos:Number = clip.y;
    clip.addEventListener(MouseEvent.MOUSE_DOWN, beginDrag);

    function beginDrag(event:MouseEvent):void
    {
        clip.startDrag();
        if (int(clip.name.substr(4)) == correctNum){
            isItRight = true;
        }
        this.beingDragged = true;
        setChildIndex(clip, numChildren - 1);
        clip.addEventListener(MouseEvent.MOUSE_UP, endDrag);
    }

    function endDrag(event:MouseEvent):void
    {
        if (this.beingDragged) {
            this.beingDragged = false;
            clip.stopDrag();
            if ((isItRight) && (clip.hitTestPoint(targ.x, targ.y, true))){
                trace(targ.name + " has been hit.");
                clip.x = targ.x;
                clip.y = targ.y;
                win_animal_food();
            } else {
                isItRight = false;
                clip.x = xPos;
                clip.y = yPos;
            }
        }
    }
}

function win_animal_food():void {
    const BALLOON_ROW:int = 4;
    var count:uint = 0;
    var altX:uint = 0;

    var bBalloon:blue_balloon = new blue_balloon;
    var gBalloon:green_balloon = new green_balloon;
    var oBalloon:orange_balloon = new orange_balloon;
    var pBalloon:purple_balloon = new purple_balloon;
    var rBalloon:red_balloon = new red_balloon;
    var yBalloon:yellow_balloon = new yellow_balloon;

    var balloonList:Array = [bBalloon, gBalloon, oBalloon,
        pBalloon, rBalloon, yBalloon, bBalloon, gBalloon,
        oBalloon, pBalloon, rBalloon, yBalloon, bBalloon,
        gBalloon, oBalloon, pBalloon];
    var balloonY:Array = [144, -205, -265, -325];
    var balloonX:Array = [0, 140, 284, 428, 68, 212, 356, 500];

    for (var ballY:uint = 0; ballY < balloonY.length; ballY++){ //Where balloons
        for (var ballX:uint = altX; ballX < altX + BALLOON_ROW; ballX++){ //get added
            var balloonName:String = ("balloon" + count);
            var balloonClip:MovieClip;
            balloonClip = balloonList[count];
            balloonClip.x = balloonX[ballX];
            balloonClip.y = balloonY[ballY];
            balloonClip.name = balloonName;
            addChild(balloonClip);
            trace(balloonClip.parent);
            trace(balloonClip + " has been added!");
            balloonClip.addEventListener(MouseEvent.CLICK, balloonPop); 
            count++;
        }

        if (altX == 0) {
            altX = BALLOON_ROW;
        } else {
            altX = 0;
        }
    }

    function balloonPop(event:MouseEvent):void {
        event.target.play();
        event.target.removeEventListener(MouseEvent.CLICK, balloonPop);
    }
}

I thought there might have been a problem with my balloon MovieClips, so I subbed them in the food array:

var birdSeed:blue_balloon = new blue_balloon;
var catFood:green_balloon = new green_balloon;
var chickenFeed:orange_balloon = new orange_balloon;
var chocolate:purple_balloon = new purple_balloon;
var dogFood:red_balloon = new red_balloon;
var duckFood:yellow_balloon = new yellow_balloon;

They all showed up on the stage, so there's nothing wrong with the MovieClips.

Added: The first values of balloonXArray and balloonYArray were originally -4 and -145 respectively, but when I started having problems I wanted to make sure the balloons were showing up so I set the first values to 0 and 144 the balloon height and width are both 144 and their cross (not sure on it's name) is in the top left corner.

Added: The reason why there are multiple instances of the same balloon in the balloonList is because I need four rows of four balloons, but only have six different balloons.

I know the balloons are on the stage because the debug display shows their x and y values on the viewable stage. Using trace(foodClip.parent) and trace(balloonClip.parent) shows that the balloons and food all have the same parent, MainTimeline, so I know the balloons aren't getting added to some different space.

I have searched online, but have not come across anyone with a similar problem. Thus, I am asking on this forum if anyone can tell me why my balloons will not show up on the stage.

Please and thank you.

Answer 1

One thing I see straight off in the baloonList is that you have the same object instances listed multiple times. Each instance can only exist on stage exactly once. If you addChild() an instance that is already on stage, the instance is first removed, then re-added at the top of the display list.

You should change:

var bBalloon:blue_balloon = new blue_balloon;
var gBalloon:green_balloon = new green_balloon;
var oBalloon:orange_balloon = new orange_balloon;
var pBalloon:purple_balloon = new purple_balloon;
var rBalloon:red_balloon = new red_balloon;
var yBalloon:yellow_balloon = new yellow_balloon;

var balloonList:Array = [bBalloon, gBalloon, oBalloon,
    pBalloon, rBalloon, yBalloon, bBalloon, gBalloon,
    oBalloon, pBalloon, rBalloon, yBalloon, bBalloon,
    gBalloon, oBalloon, pBalloon];

to:

var balloonList:Array = [
    new blue_balloon, 
    new green_balloon, 
    new orange_balloon,
    new purple_balloon,
    new red_balloon,
    new yellow_balloon, 
    new blue_balloon, 
    new green_balloon, 
    new orange_balloon,
    new purple_balloon,
    new red_balloon,
    new yellow_balloon, 
    new blue_balloon,
    new blue_balloon, 
    new green_balloon, 
    new orange_balloon,
    new purple_balloon
];